função EXPREG

Sumário

# EXPREG

Corresponde e extrai ou, opcionalmente, substitui o texto usando expressões regulares.

### Sintaxe

EXPREG( Texto ; Expressão [ ; [ Substituição ] [ ; Opções | Ocorrências] ] )

Texto: um texto ou referência a uma célula na qual a expressão regular deve ser aplicada.

Expressão: Um texto representando a expressão regular, mediante a sintaxe de Expressões Regulares ICU. Caso não haja correspondência e Substituição não for dado, devolve #N/D.

Substituição: opcional. O texto de substituição e referências para grupos de captura. Se não houver correspondência, o Texto é retornado sem modificações.

Opções: Opcional. "g" substitui todas as correspondências de Expressão no Texto, sem extração. Se não houver correspondência, o Texto é retornado sem modificações.

Ocorrência: Opcional. Um número para indicar que ocorrência de Expressão em Texto deve ser extraído ou substituído. Senão houver ocorrência e Substituição não existir, retorna #N/DISP. Se não houver ocorrência e houver Substituição, retorna Texto sem modificações. Se Ocorrência é zero, retorna Texto sem modificações.

### Exemplos

=EXPREG("123456ABCDEF";"[:digit:]";"Z") retorna "Z23456ABCDEF", onde a primeira ocorrência de um dígito é substituída por "Z".

=EXPREG("123456ABCDEF";"[:digit:]";"Z";"g") retorna "ZZZZZZABCDEF", onde todos os dígitos são substituídos por "Z".

=EXPREG("123456ABCDEF";"[126]";"";"g") retorna "345ABCDEF", onde todas as ocorrências de "1", "2" ou "6" são substituídas pelo texto vazio, por consequência, excluídos.

=EXPREG("axbxcxd";".x";;2) retorna "bx", a segunda ocorrência de ".x".

=EXPREG("axbxcxd";"(.)x";"$1y";2) retorna "axbycxd", a segunda ocorrência de "(.)x" (i.e. "bx") substituída pelo grupo de captura de um caractere (i.e. "b") seguido por "y".

#### Informação técnica

Esta função está disponível desde o LibreOffice 6.2.

Esta função não faz parte do padrão Open Document Format for Office Applications (OpenDocument) Versão 1.3. Parte 4: Formato de Fórmula Recalculada (OpenFormula). O espaço de nomes é

ORG.LIBREOFFICE.REGEX

Tópicos relacionados

Página wiki da função EXPREG.

Lista de expressões regulares

Expressões regulares ICU

Funções de texto

♥ Doe para nosso projeto! ♥