#compdef swaymsg
#-----------------
# Description
# -----------
#
# Completion script for swaymsg in sway wm (http://swaywm.org)
#
# ------------------------------------------------------
# Author
# --------
#
#  * Seth Barberee <seth.barberee@gmail.com>
#
#  -------------------------------------------

types=(
'get_workspaces'
'get_seats'
'get_inputs'
'get_outputs'
'get_tree'
'get_marks'
'get_bar_config'
'get_version'
'get_binding_modes'
'get_binding_state'
'get_config'
'send_tick'
'subscribe'
)

_arguments -s \
	'(-h --help)'{-h,--help}'[Show help message and quit]' \
	'(-m --monitor)'{-m,--monitor}'[Monitor until killed (-t SUBSCRIBE only)]' \
	'(-p --pretty)'{-p,--pretty}'[Use pretty output even when not using a tty]' \
	'(-q --quiet)'{-q,--quiet}'[Be quiet]' \
	'(-r --raw)'{-r,--raw}'[Use raw output even if using a tty]' \
	'(-s --socket)'{-s,--socket}'[Use the specified socket path]:files:_files' \
	'(-t --type)'{-t,--type}'[Specify the message type]:type:{_describe "type" types}' \
	'(-v --version)'{-v,--version}'[Show the version number and quit]'
