###############################################################################
# encompass.des: Full level (encompassing) vaults for the main dungeon go here.
#                For encompass vaults that go in branches (eg branch endings)
#                use the des file for that branch.
###############################################################################

default-depth: D:12-26

###############################################################################
# The River Lethe
#
# Should be turned into a timed, non-announced portal vault
# using the maprot (or unmappable) flag.
#
# The two orange statues are placed for maximum pain -- one you're
# likely to first see while levitating, the other is hard to target
# with disintegration through its protective plants.
#
# Lemuel
#
NAME:    lemuel_river_lethe
ORIENT:  encompass
TAGS:    no_rotate
DEPTH:   D:16-26
SUBST:   + = +=
SUBST:   . = .:100 !:1 6:4
SUBST:   ; = .:200 !:1 1:3
SUBST:   1 = 1:20 .
SUBST:   3 = 3:20 .
KFEAT:   ! = ^
MONS:    plant
MONS:    wolf / warg / hell hound
MONS:    nothing
MONS:    wight w:50 / wraith / shadow wraith / phantasmal warrior /\
         skeletal warrior / flayed ghost
MONS:    dancing weapon
MONS:    human simulacrum w:60 / elf simulacrum / ogre simulacrum /\
         centaur simulacrum / troll simulacrum / vampire / wraith / hungry ghost
MONS:    eye of draining / brain worm / death drake w:5 / shadow /\
         shadow dragon w:1
KITEM:   A = potion of experience / any good_item
KMONS:   A = Maud
KFEAT:   A = >
KFEAT:   B = |
KMONS:   B = neqoxec
KFEAT:   C = b
KMONS:   C = lich w:20/shadow fiend
SUBST:   b = b|
SUBST:   | = |*
ITEM:    any scroll, potion of experience
SHUFFLE: dD/eE/fF/gG
SUBST:   D==, d=|, E=x, e=%%*, F=x, f=%, G=x, g=%
SHUFFLE: PQ
SUBST:   Q=xw
KMONS:   P = orange crystal statue
KFEAT:   P = floor
KMONS:   k = giant eyeball
KITEM:   k = potion of experience / any good_item
NSUBST:  r = 1:+ / *:x
NSUBST:  R = 1:= / *:x
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxccccccccccccxxxxxx
xxAB.r$xxxwwwxxxxcccccccccccccccccccccccccccxxxxxxxxcc..1....|kcxxxxxx
xwBB.r$$Rwwwwxxxxc.....+...+...........c***c;;xxxxx;cc.....1.||cxxxxxx
xw...r$$Rxwwwxxxxc..C..ccccc...........c***c;;;xxx;;cc.1.1...1.cxxxxxx
xww..r$$Rxwwwwxxxc.....cxxxc...........c***c;;;;xx;;;+.....1..1cxxxxxx
xww..xxxRwwww;xxxc..}..cxxxc...........c...c;;;;xx;;cc..1.111..cxxxxxx
xwww.xxxwww;;;;xxccccccccxxcc+ccc+ccccccc+cc;;;;xx;;cc.11111...cxxxxxx
xwwwxxxwwww;;;;;xxxxxxxxxxxc...c...c.......c;;;;x;;;cc..111H..1cxxxxxx
xwwwxxxwwwww;;7;;xxxxxxxxxxc...c...c.w.....c;;;;;;;;cc.111111..cxxxxxx
xwwwxxxwwwww;;;;;;;xxxxxxxxc...+...c.w.....+;;;;;;;;cc..111..1.cxxxxxx
xwwwxxxwwww;;7;;;;;;;;xxx;;c...c...c.w.....c;;;;;;;;ccccccccccccxxxxxx
xwwwxxxwww;;;;;;;;;;;;;;;;;cc+ccc+cc..w....c;;;;;;;;;;xxxxxxxxxxxxxxxx
xwwwxxxwww;;7;;;;;;;;;;;;;;+.......+..w....cccc;;;;;;xxxxxxxxxxxxxxxxx
xwwwwxx;ww;;;;;;;;;;;;;;;;;cccc+cccc...w...c$$c;;;;;;;;xxxxxxxxxxxxxxx
xwwwwxx;w;;7;;;;cccc;;;;;;;c.......c...w...c$$c;;;;;;;;;;;xxxxxxxxxxwx
xwwwwxx;;;;;;;;cccccc;;;;;;c.......c+ccwwccc+cc;;;;;;;;;;;;;xxxxxxxxwx
xwwwwxx;;;7;;;cc*4.+;;;;;;;c.......c.c..ww....c;;;;;7;;;;;;;;xxxxxxwwx
xxwwwwx;;;;;;;;cccccc;;;;;;c6.6.6.6c.c...ww...c;;;;;;;;;;;;;;;xxxxxwwx
xxxwwwxx;;;;;;;;cccc;;;;;;;ccccccccc.c...ww...c;;;;;;;;;;;;;;;xxxxxwwx
xxxwwwxx;;;;;;;;;;;;;;;;;;;c$$+....+.c....www.c;;;;;;;ccccccccxxxxxwwx
xxxwwxx;;cccc;;;;;;;;;;;;;;c$$cccccc.c.....wwwc;;;;;;;c.....$$Dddxxwwx
xxxwwwx;cccccc;;;;;;xx;;;;;c$$c....c+cccccccwww;;;;;;;c.....$$xdd+wwwx
xxxwwwxcc*4.+;;;;;;xxxx;;;;cccc....c.....c...www;;ccccc.......xxxxxwwx
xxxwwwxxcccccc;;;;xxxxx;;;;;;;c....c.....+...www;;c...c.......xeexxwwx
xxxwwwxx;cccc;;;;xxxxxx;;;;;;;c....c.....c...www;cc.66c.......Eee+wwwx
xxxwwwxx;;;;;;;;xxx5..c;;;;;;;cccccc.....cccwww;;;+.66+.......xxxxxwwx
xxxwwwxx;;;;;;;;;xx5..c;;;;;;;;;;;;c.....c;wwww;;cc.66c.......Fffxxwwx
xxxwwwxx;;;;;;;;;;x5..+;;;;;;;;;;;;cccccccwwww;;;;c...c.......xff+wwwx
xxxwwwxx;cccc;;;;xxx..c;;;;;;;;;;;;;;;;;wwwwww;;;;ccccc.......xxxxxwwx
xxxwwwxxcccccc;;;;;xx.c;;;;;;;;;;;;;;;;wwwwwww;;;;;;;;c.....$$xggxxwwx
xxxwwwxcc*4.+;;;;;;xxxx;;;;;;;;;;;;;;;wwwwwwwww;;;;;;;c.....$$Ggg+wwwx
xxxwwwxxcccccc;;;;xxxwxx;;;;;;x;;;;;wwwwwwwwwww;;;;;;;ccccccccxxxxxwwx
xxxwwwxxxcccc;;x;;;xwwxxx;;;;;xx7wwwwwwwwwwwwww;;;;;;;;;;;;;;;xwwwwwwx
xxxwwwxxxxwww;;;;;;wwwwxw;;;;xxxwwwwwwwwwwwxxwww;;;;7;;;;;wwwwwwwwwwwx
xxxwwwxxxxxwwwwwwwxwwwwwwwwwxxxwwwwwwwwwwwwxxxwwwwww;;wwwwwwwwwwwwwwxx
xxxxwwwwxxxxwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwxxxxwwwwwwwwwwwwwwwwwwwwwxxx
xxxxwwwwwwwwwwwwwwwwwwwwwwwwwwwwwxwwwwwwwxxxxxwwwwwwwwwwwwwwwwwwwxxxxx
xxxxwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwxxxwwwwwwwwwwwwwwwwwwxxxxxxx
xxxxxwwwwwwwwwwwwwwwwQxwwwwwwwxxwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwxxxxxxxx
xxxxxxwwwwwwwwwwwwwxxxxwwwwwwwwwwwwwxxxPwwwwwwwwwwxxwwwwwwwwxxxxxxxxxx
xxxxxxxwwwwwxxxxxxxxxxwwwwwwwxxwwwwxxxxxwwwwwwwwwxxxwwxwwwwxxxxxxxxxxx
xxxxxxxx;7;;xxx222xxxxxxwwwwxxwww2222xxxxx22wwwwwwxxxxxxxxxxxxxxxxxxxx
xxxxxxxx;;;xxx;;;;;xx2222wwwwww;;;;;;;;xxxx22;;;;wwwwxxxxxxxxxxxxxxxxx
xxxxxxxxx;xxxx;;;;;;;;;;;;ww;;;;;;;;;;;;;;;;;;;;;;;;wwwxxxxxxxxxxxxxxx
xxxxxxxxxxxx;;;;2;;;;;;;;;;;;;;;;;);;;;;;2;;;;;;;;;;wwwxxxxxxxxxxxxxxx
xxxxxxxxxxxx;;;;;;;;;;;;;;;;;;;;;[](;;;;;;;;;;;;;;;;2wxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx+xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx.xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx{xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx.xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##############################################################
# Sea of Fire
#
# By minmay.
#
# All arrivals from above (and one from below) bubbles just lead to
# downward escape hatches. The other two staircases from below lead
# to bubbles with some loot. For the main fight, you have to levitate
# or teleport.
# The opposition is nasty, but this map is deep enough.
NAME:    minmay_sea_of_fire
TAGS:    no_rotate
ORIENT:  encompass
DEPTH:   D:16-24
MONS:    hell hound / nothing
MONS:    lindwurm
MONS:    fire drake / steam dragon w:1
MONS:    fire giant / dragon / mottled dragon w:5 / efreet w:2
MONS:    smoke demon
MONS:    hell knight / nothing w:5
KMONS:   7 = molten gargoyle
KFEAT:   7 = l
KMONS:   8 = iron golem
KMONS:   9 = Xtahua, hellephant
KMONS:   $ = 0 / nothing w:90
KITEM:   $ = $
NSUBST:  = = 1:= / *:v
SUBST:   = = =v
SUBST:   ' : l.
: _G.set_random_mon_list("fire bat w:30 / fire drake / dragon / hell hound / " ..
:     "efreet / fire crab / fire giant w:3 / mottled dragon / " ..
:     "fire elemental / crimson imp / fire vortex / molten gargoyle")
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxvvvvvvvvvvvvvvvvvvvvxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxllllxxxxxxxxxlllllxxxll.3..v$$$$$$$$v......0..vxxxxxx.....xxxxxxx
xxxxxxxxxxxxxllllllllllxxxxllllllllllll...=$$$$$$$$+....0....vxxxx....0....xxxxx
xxxxxxxxxxxlllllxxllllllllllllllllllllllllvv=$$$$$$v..vvvvv.0vxll0..>.......xxxx
xxxxxxxxxlllllllllllllllllllllllllllllllllllv$$$$$$v4.v...v..vllll.....x..0..xxx
xxxxxxxllxxxxxllllllllllllllllllllllllllllllvvv$$$$v..v.].v..vllllll.0.......xxx
xxxxxxlxxx..1xxx..lllxx.0..llxxlllllllllllllllv$$$$v......v..vlllllllll.......xx
xxxxxlxx..1.....x...........xx..llllllllllllllvvvvvvvvvvvvv++vllllllllxx.0.x..xx
xxxxlxx..xxxx1..1.x........0......lllllllllllllxxxxxllxxxll.3llllllllllxxxxx..xx
xxxxlx.1xx{.x.........x............llllllllllllllxxllllllll..llllllllllllxxxx.xx
xxxxlx..xxx.xl1..1..............2>.lllllllllllllllllllll.......lllllllllllxxx..x
xxxllxx..1.xxl.........0.....0.....lllllxllllllllllll...x..........lllllllxx...x
xxxlllxx..xxlll1...x.............xlllllxxllllllllllx........x...xll.llllllx[...x
xxlllllxxxxlllllll........0....llxxllxxxllllllllll.....x...xx6.6xlll.lllllxxx..x
xllllllllllllllllllll....x.llll.llxxxxxxllllllllllx...xx6.6xxx..xxll.llllllxxxxx
xllllllllllllllllllllllllllllll.llllxxlllllllllllxx6.6xx..xxxxxxxxlll.lllllllxxx
xlllllllllllllllllllllllllllllll.llllllllllllllllxxxx.xxxxxxxxxxxxllll.lllllllxx
xxllllllllllllllllllllllllllllll.lllllllllllllllxxxxxxxxxxxxxxxxxllllll..lllllxx
xxxllllllllllxxllllllllllllllllxx.llllllllllllllxxxxxxxxxxxxxxxxllllllx..ll...xx
xxxlllllllllxxxxllllllllllllllxxxx...llllllllllllxxxxxxxxxxxxxllllllll..3..lll<x
xxlllllllll..>xxlllllllvvvvvvvvvvxxx3.xxxllllllllllxxxxxxlllllllllllllll..lllllx
xlllllllll....xxllllllxv..0....*vxxxxxxvvvvvvvvlllllllllllllllllllllllllllllllxx
xlllllllll..3..xllllllxv..0...4*vxxxxxxv.4v...vlllllllvvv7vvv7vvv7vvv7vvv7vvvlxx
xxlllllllll....llllllxxv..vvvvvvvvvvvvvv..v.}.vxllllllvvvvvvvvvvvvvvvvvvvvvvvllx
xxllllllllll..lllllllxxv...........0......v...vxllllllvv.4***||v...v9.**|||vvllx
xxllllllllllllllllllllxv....0.0.....0.....v...vxxlllll7v4.***||v.>.v...***|v7llx
xxxllllllllllllllllllllv.vv.....vvvvvvvv......vxxlllllvv..vvvvvv...vv....*vvvllx
xxxllllllllllllllllllllv..v.0.0.vlxxxxxv......vxllllllvv4......vv+vv.......vvlxx
xxxllllllllxxllllllllllv4<v.....vllllxxvvvvvvvvlllllllvv...4...v...v.......vvlxx
xxxlllllllxxxxxllllllllvvvv..vvvvlllllxxxlllllllllllll7vvvvv..vv...vvvv++vvv7lxx
xxllllllllxxxxllllllllllll..3.llllllllllllllllllllllllvv4.....v6...6v8....8vvlxx
xllllllllllxxllllllllllllll..llllllllllllllllllllxxlllvv......v.....v......vvllx
xllllllllllllllllllllllllllll.llllllllllllllllllxxxxllvv......v6...6v......vvllx
xxlllllllllllllllllllllllllll.lllllllllllllllllxxxxxll7v......v.....v8....8v7llx
xxllllllllllllllllllllllllllx.xllllll...lllllllxxxxlllvv.....4v6...6vvv++vvvvllx
xlllllllllllllllxxlllllllll...xxllll..0....xlllllxxlllvv..vvvvvv...vv......vvlxx
xllllllllllllllxxxxlllllll.xxx.xll......xx....llllllllvv.......v...v.......vvlxx
xllllllxxllllllxxvvvvllll.lxxxl...lll..xx...0..lllllll7v..............v..v.v7lxx
xxlllllxxxlllllllv00v.l..llllllllllll...0......lllllllvv.......v...v.......vvlxx
xxlllllllllllllllv00v..lllllllllllllll.........lllllllvv......vv...vv......vvlxx
xxxllllllllllllllvvv.vvvlllllllllllllll..x....llllllllvv1vvvv1v3...3v.v..v.vvlxx
xxx...lllllllllllv**v00vlllllllllllllll..0..xlllllllll7v1v**v1v.....v......v7lxx
xxx1....lllllllllv**v00vllllllllllllllll.....lllllllllvv1....1v.....v4....4vvlxx
xxxx.x.1.llllllllvvvvvvvllllllllllllllxx...0..lllllllxvvvvvvvvv.....vvvvvvvvvllx
xxxx1..xxxxxlllllllxxxxxllllllllllllllxxxx....llllllxxvvv7vvv7v+++++v7vvv7vvvllx
xxxx..xxxxxxxxllllllxxllllllllxxxllllllxxxx..llllllxxxxxlllllll8...8lllllllllllx
xxxx.3xxxxxxxxxxlllllllllllllxxxxxllllllxx.llllllllxxxxlllllllll8.8llllllllllllx
xxx...xxxxxxxxxxxllllllllllllxxxxxlllllll.lllllllllllxxlllllllllllllllllllllllxx
xxx..xxxxxxxxxxxxxlllllllllllllxxxlllllll.llllllllllllllllllllllllllllllllllllxx
xx...xxx>%%xxxxxxxllllllllllllllllllllll.lllllllllllllllllllllllllllllllllllllxx
xx...xxxx%%.xxxxxxlllllllllllllllllllllll.lllllllllllllllllxxlllllllxxxxxllllllx
x.1..xxxxxx.xxxxxllllllllxxllllllllllllll.lllllllllllllllllxxxxllllxxxxxxxxllllx
x.....xx...xxxxxlllllllllxxxlllllllllllll.llllll....lllllllxxxlllllxxx$$$xlxlllx
x.x.1...xxxxxxxxlllllllll..xllllllllllll.lllllll.0....lllllllllllllxx$$$$$xxllxx
x......xxxxxxxxlllllll...x......llllllll.llllll.x...0.llllllllllllxxx$>$$xxxllxx
x.1..x..xxxxxxlllllll.ll.....lll.lllll...xlllll...>...llllllllllllxx$$$$xxxlllxx
xx........llll''''ll'lll.v++vllll..l...3...ll...0...x.llllllllllllxxx$$xxxxlllxx
xx.1..........llll''lllvvv..vvvllll....x.....xx....0..xxlllllllllllxxxxxxxlllxxx
xxx........xllllllllllvv......vvllllxx...xxxxxxx..x..xxxxxllllllllllxxxllllllxxx
xxxx..x.1..xxlllllllllv.0......vlllllxxxxxxxxxxxx....xxxxlllllllllllllllllllxxxx
xxx.......1.xxlllllllvv...vv0..vvlllllxxxxllxxxxxx.xxxxllllllllllllllllllllxxxxx
xxx.x..3....xxlllllllv...v%%v..0vllllllllllllllxxxxxxxlllllllllllllllllllxxxxxxx
xx..x.......xlllllllxv0..v%%v...vllllllllllllllllxxxxlll..1.llll..1.llllxxx...xx
xx.xx...x..llllllllxxvv...vv...vvllllllllllllllllllllll1llll.1...x....lxxx).x..x
x.xxxx1...lllllllllxxxv..0.....vllllllllllll.xlllllll..llllllll.1....xxxxxxxxx1x
x.xxxxxx..lllllllllllxvv.....0vvlllllllllll....lll..1lllllllllll..xx1....xxx1..x
x.xxxxxxxllllllllllllllvvv..vvvllllllllllll..5....llllllllllllxxxxxxxx...1....xx
xx(xxxxxxxxllllllllllllllv++v...lllllllllxxxx<..llllllllllllxxxxxxxxxxxxx..1.xxx
xxxxxxxxxxxxxxxllllxxxlll........llllxxxxxxxxx...llllllllxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##############################################################################
# The New Box Level (dp)
#
NAME:    box_level_dp
DEPTH:   D:20-26
ORIENT:  encompass
TAGS:    no_pool_fixup no_rotate
SHUFFLE: zZ
NSUBST:  A = 1:= / *:b
NSUBST:  B = 1:= / *:b
NSUBST:  C = 1:= / *:b
NSUBST:  D = 1:= / *:b
NSUBST:  E = 1:= / *:x
KFEAT:   ^ = teleport trap / Zot trap
SUBST:   ':''l. , '=l.
SUBST:   ":""W. , "=Ww..
ITEM:    ring of teleportation
ITEM:    royal jelly / honeycomb w:20 / nothing w:30
ITEM:    scroll of teleportation
KFEAT:   T = teleport trap
KMONS:   w = electric eel / jellyfish / nothing w:120
KFEAT:   w = w
KMONS:   l = fire vortex / lava snake / lava fish / fire elemental w:1 /\
             nothing w:50
KFEAT:   l = l
KMONS:   z = killer bee
KMONS:   Z = bumblebee
KITEM:   z = royal jelly / honeycomb w:20 / nothing w:120
KITEM:   Z = royal jelly / honeycomb w:20 / nothing w:120
: if crawl.one_chance_in(3) then
KMONS:   ! = orc / orc warrior / orc knight / nothing w:30
KMONS:   & = orc warlord / orc knight / nothing w:20
: elseif crawl.coinflip() then
KMONS:   ! = yaktaur / nothing
KMONS:   & = yaktaur captain / nothing
: else
KMONS:   ! = naga / nothing
KMONS:   & = naga warrior / greater naga
: end
SUBST:   * = * % % $ $ f
SUBST:   ; = 9 0
SUBST:   !=%$, &=*%
SUBST:   _ : _+ , _ = +=
SUBST:   V = *
COLOUR:  a = yellow
TILE:    a = wall_wax
SUBST:   a = x
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
x.......xccccccxxxxxxx.........................................w"..xxx
x.(...{.xc....cbbbbbxx................xxx...................."w......x
x.......++.U..++.].++.....'''....'l'....xxx................."ww"..)..x
x...[...xc....cbbbbbxx...'''..''lllll'....xx...vvEvvEv......"ww"....xx
x.......xcccccccxxxxxx.......'llllllll.....x...vd...9v...."www".....xx
xxxxxxxxxxxxxxxxxxxxxx.......'lllllll'.....x...E.....E.."ww.w".....xxx
x.............................'lllll'.....xx...v9...Vv.www..w".....xxx
x....""w.............".xxx......'ll'......x....vvEEEEvwww.www.....xxxx
x.."wwwww"..........w....xxxx............xx....."wwwwwwww.ww"....xxxxx
x.wwwwwwww"........w........xxxxxxx....xxx........"www"...ww"...xxxxxx
x..wwwwwww"......"ww......""......xxxxxx....."...........ww"....xxxxxx
xx..""ww".......www....."wwwwwwwwww........."www"......wwwww"....xxxxx
xxx.........."wwww"..""wwwwwwwwwwwwwwwwww".www"...wwwwwwwwwwww.....xxx
xxxxx....""wwwwwwwwwwwwwwww.......wwwwwwwwwwwwwwwwwwwwwww.....xx....xx
xxx..""wwwwwwwwwwwwwwww"......G.G......"wwwwxxww".........xxxxx.....xx
x."wwwwwwwwwwwwwxxx__xxxxxxxxxx=xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx....x
xwwwwwwww".."wwwxww.."w........................................>xx...x
xxwwww""....."xwxw"...ww........................................xx...x
xxww".........xxxw..............................................xx..xx
xww............xx"w...ccccccccccccccccccncccccccccccccccccc.....xx..xx
xw"...xxx.......x..w..c^..*...*...*...*...*...*...*...*...c.....x...xx
xw....x!x..xxx..x..w..c...................................c.....x...xx
xxx...x+x..x!x..x.....c*..;...;...;...;...;...;...;...;..*c.....xx..xx
xxx....1..1+!x..x.....c...................................c.....xx...x
x..........xxx.xx.....c.......bbbbbbbbbb.bbbbbbbbbb.......c.....xx..xx
x..xxxx........xx.....c.......bTTTTTTTTTbTTTTTTTTTb.......c.....x...xx
x..x!!+1..xxxx..x.....c*..;...bTbbbAbbbTbTbbbBbbbTb...;..*c.....x..xxx
x..xxxx..1+!!x..x.....c.......bTb8...|bTbTb|...8bTb.......c.....xx.xxx
x.........xxxx..x.....c.......bTA|...|ATbTB|...|BTb.......c.....xx.xxx
x.......1.......x.....c.......bTb|...8bTbTb8...|bTb.......c.....x...xx
xxx....121....xxx.....c*..;...bTbbbAbbnTbTnbbBbbbTb...;..*c.....x...xx
x!x...cc+cc...xxx.....c.......bTTTTTTTTTbTTTTTTTTTb.......c.....xx..xx
x&+1..c!2!c...xxx.....n........bbbbbbbbbTbbbbbbbbb........n.....x..xxx
x!x...c&&&c...xxx.....c.......bTTTTTTTTTbTTTTTTTTTb.......c.....x..xxx
xxx...ccccc...xxx.....c*..;...bTbbbDbbnTbTnbbCbbbTb...;..*c.....x.xxxx
x...............x.....c.......bTb|...8bTbTb|...8bTb.......c.....x.xxxx
xx...1...xxxx...x.....c.......bTD|...|DTbTC|...|CTb.......c.....x..x.x
xx..x+x.1+!!x...x.....c.......bTb8...|bTbTb8...|bTb.......c.....xx...x
x...x!x..xxxx...x.....c*..;...bTbbbDbbbTbTbbbCbbbTb...;..*c.....xxx.xx
x...xxx.........x.....c.......bTTTTTTTTTbTTTTTTTTTb.......c.....xxx.xx
x.........xxxxxxx.....c.......bbbbbbbbbb.bbbbbbbbbb.......c.....xxx..x
xxxx......x***99+.....c...................................c.....xxxx.x
xxxx..xx..xxxxxxx.....c*..;...;...;...;...;...;...;...;..*c.....x....x
x.....xx........x.....c...................................c.....x.xx.x
x.xx.....xxx....x.....c...*...*...*...*...*...*...*...*..^c.....x.xx=x
x.xx....1+!x..xxx.....ccccccccccccccccccncccccccccccccccccc.....xxx..x
x....xx..xxx..xxx...............................................xx..xx
x....xx.......xxx.........................................z..z..x....x
xx............xxx<.............................................zxa...x
xx..x......xx...xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx_x_x_xxazzxx
xxx........xx.....xxx...xx.x..xx...xxaaaaaaaeaaea.a..aaaaaaa.aaaaazzxx
xxxx..xx..............x...x...xx.xx.xaaazazzaaza.a.aa.za.z.aaaa.a.aazx
xxxxxxxxxxx....x..xx.x.xx.x..x..xx}..xaeazaazzazzaa..aa..aa....z.aeaxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##############################################################################
# A mockup of the Forest branch (1KB)
#
NAME:    spriggan_forest
DEPTH:   D:19-26
ORIENT:  encompass
TAGS:    no_pool_fixup
MONS:    spriggan, spriggan rider, spriggan druid, spriggan berserker
MONS:    spriggan air mage, spriggan defender, the Enchantress
SUBST:   . = .:300 / 1:2 / 2:1 / 3:1 / 4:1 / 5:1
SUBST:   T = t / t / P / .
KMONS:   P = plant / plant / bush / nothing
KMONS:   R = plant
KMONS:   Q = bush
KMONS:   d = spriggan spells:pain;bolt_of_draining;animate_dead name:necromancer n_suf col:magenta
KMONS:   e = bat skeleton name:skeletal_bat n_rpl n_spe n_des n_zom
KMONS:   K = giant firefly
KITEM:   f = dagger / short sword / sabre / flail / whip / blowgun / bow
KITEM:   g = robe / cloak / cap / buckler / steam dragon armour w:1
KMONS:   L = spriggan col:white name:baker n_suf ; robe . dagger
KITEM:   h = bread ration q:2
KMONS:   M = yak
KMONS:   N = spriggan name:shepherd n_suf ; robe . quarterstaff
KITEM:   i = cheese q:3
COLOUR:  "MN = green
COLOUR:  C = white
KFEAT:   C = stone_wall
TILE:    C = wall_marble
KFEAT:   _ = altar_trog
: _G.set_random_mon_list("place:Forest:3")
MAP
tttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttt
tttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttttt
ttttPP.Tttt...tttttttttttttttttttttttttttttttttttttttttttttttttTTTTTttTTTTtttttt
tccccT.....ttt..ttttttttttttttttttttttttttttttTtTTtttttttQTtttTT.T.Ttt.T.TTTtttt
tc%4c...Tttttttt.ttttttttttttttttttttttttttttT*....QQPtt..ccccc....cccc.TT.Ttttt
tc..+..Ttttttttt..ttttttttttttttttttttttCCCCCCCCCCCCCC....c..1c....c.1c.t.TTtttt
tc.4c...Ttttttt.t..tttttttttttttttttttttC.6.C6..6C$*|CtT..c.1.+....+..cT.TT.tttt
tcccct.Tttttt..tttt........tttttttttttttC7..+....+$*|Ctt..ccccc....cccc.TT.Ttttt
tttT..tttttt.tttttttttttttt.ttttttttttttC.6.C6..6C$*|CttQ..................ttttt
ttTPTTtttt...ttttttttttttttt..ttttttttttCCCCCC++CCCCCCttttccccc....cccc......ttt
ttTTtttttt..ttttttttttttttttt.ttttttttttCgggC....CfffCttttchxLc....c1.c.....tttt
tttttttt...ttttttttttttttttttt.tttttttttCggg+..1.+fffCttttch..+....+.5c..1...ttt
tttttt.tttt..ttttttttttttttttt.tttttttttCgggC1...CfffCttttccccc....cccc...1.tttt
tttttt.ttttt.tttttttttttttt.....ttttttttCCCCCC++CCCCCCttttt...................tt
ttttt.ttttt..ttttttttttt...tttT..tttttttCR.....1....RCccccccccc....Y.........ttt
ttt..tttttt..ttttttttt..tttttttt.tttttttC..1........1CcKxKxKxKc......2......tttt
tt.ttttttt.tttttttt...ttttttttttt.ttttttCR1..5..5..1RCc.22.1..c.....22......tttt
tt.tttttt.ttttttt...1.tttttttttttt.tttttCCCCCC++CCCCCCc+ccccccc....2.2.....ttttt
ttt.tttt..tttttt...22..tttttttttttt.tttt..................................tttttt
tttt..[t.ttttttt..1..2.)tttttttttttt.....................................ttttttt
ttttt....ttttttt.t.1...tttttttttttt.tt..TTttttt............Y..........ttt.tttttt
ttttttt..tttttt.tttttttttttttttttt.tttttttttttttttttt...............tttttt...ttt
ttttttttt..ttt.tttttttttttttttt....ttttttttttttttttttttt.........tttttttttttt(tt
ttttttttttt...tttttttttttttttt.tt..ttttttttttttttttttttttttt....tttttttttttttttt
tttttttttttttt.tttttttttttttt.tttt.tttttttttttttttttttttttt.tt...ttttttttttttttt
tttttttttttttt.ttttttttttttt.WWWWt.ttttttttttttttttttttttt.ttttt...ttttttttttttt
ttttttttttttt.tttttttttttttt.Wwwwt.ttttttttttttttttttttt..ttttttt..ttttttttttttt
tttttttttttttt.ttttttttttttt.tWWWWt..tttttttttttttttt.t.ttttttttt..ttttttttttttt
tttttttttttttT.ttttttttttttt.ttWwwwwt.tttttttttttttttt.ttttttttttt..tttttttttttt
ttttttttttttt..ttttttttttttt.tttwwwwww.ttttttttttttttt.ttttttttttt..tttttttttttt
tttttttttttt...tttttttttttt.tttwwwwwwww.....tttttttttt.ttttttttttt.ttttttttttttt
ttttttttt.....ttttttttttttt.ttttwwwwwwwwwwwt.tttttttt.ttttttttttt.t.tttttttttttt
ttttttt..tt..tttttttttttttt.ttwwwwwwwwwwwwwwt.tttttt.ttttttttttt..tt....tttttttt
ttttT..tttttttttttttttttttt.ttwwwwwwwwwwwwwwt.......tttttttttttt.ttttttt...ttttt
tttt....tttttttttttttttttttt.wwwwwwwwwwwwwwww..tttttttttttttttt.ttttttttt.33tttt
ttt....T..3...tttttttttttttt.wwwwwwwwwwwwwwwt.ttttttttttttttttt.ttttttttt3..tttt
tttT...ttttttt....tttttttttt.wwwwwwwwwwwwwwt.ttttttttttttttttt.ttttttttttt..tttt
ttt..]..ttttttttt......ttttt.Wwwwwwwwwwwwtt.tttttttttttttttttt.ttttttttttt.ttttt
ttt........tttttttttttt.......WWwwwwwwwttt.tttttttttttttttt...tttttttttttttttttt
tttt..111.tttttttttttttttttttt...........ttttttttttttt.....ttttttttttttttt..tttt
ttttT.1...tttttttttttttttttttttttt.tttttttttttttttttt.ttt.ttttttttttttttttt.tttt
ttttTT.1....ttttttttttttttttttttt.tttttttttttttttttt.ttttt.ttttttttttttttt..tttt
ttttttt.tttt...ttttttttttttttttt..tttttttttttttttt..ttttttt..ttttttttttttt.ttttt
tttttt.tttttttt...ttttttttttttt.tttttttttttttttt..ttttttttttt....tttttttt.tttttt
ttttt..tttttttttt.ttttttttttttt.tttttttttttttttt.ttttttttttttttt.........ttttttt
ttttt.ttttttttttt.tttttttttttt.3.tttttttttttttt.ttttttttttttttt.ttt..t..tttttttt
tttt..tttttttttt..tttttttttttt3G3ttttttttttttt.tttttt.tttttttt.ttttttt....tttttt
ttttt.ttttttttt..ttttttttttttt.3.tttttttttttt.t.tttttt.....tt.tttttttttt...ttttt
tttt.tttttttttt.t..tttttttttttttttttttttttt..ttt.tttttttttt...ttttttttttt..ttttt
tttt.ttttttttt..ttt...ttttttttttttttttttttt.ttttt.ttttttttwwwtttttttttttt...tttt
ttttt.tttttttt.tttttt...tttttttttttttttt...tttttt.tttttttttwwttttttttttttt..tttt
ttttt.tttttttt{tttttttt......ttttttttt.....ttttt.ttttttttttttttttttttttttt.ttttt
tttt.tttttttttttttttttttTT..t...tttt..tttttttttt.tttttttttttttttttttttttt.tttttt
tttt.ttttttttttttttttttttt.ttttt....ttttttttttttt.ttttttttttttttttttttttt.cccctt
ttttt.ttttttttttttttttttt.tttttttttt.tttttttttttt..tttttttt..tt...ttttttt.+.1ctt
tttttt.ttttttttttttttttt.tttttttttt..tttttttttttttt.tttttt.t...ttt..tttttTc1%ctt
ttttttt.ttttttttttttttt.ttttttttttt....xxxxxtttttttt..tttt...tttttt.ttttttcccctt
ttttttt.tttttttttttttt.ttttttttttttT...x..4xtttttttttt....ttttttttt.tttttttxxxxx
ttttttt.tttttttttttttt.ttttttttttttT...+...xtttttttttttttttttttttttt.tttxxxxxxxx
txxxtt.ttttttttttt....ttttttttttttttt.tx..4xttttttttttttttttttttttttt..xxxxxxxxx
txi+"""""""tt......t.....ttttttttttttt.x.4_xttttttttttttttttttttttttt....xxxxxxx
txxx""""""""".tttttttt..TTtttttttttttttxxxxxttttttttttttttttttttttt......}xxxxxx
ttt""N"""""""TTtttttttt....ttttttttttttttttttttttttttttttttttttt.....xxxxxxxxxxx
ttT""MM"MM"TTTttttttttttttt..tttttttttttttttttttttt...ttttttttt....xxxxxxxxxxxxx
tt""""M""""Tttttttttttttttttt..ttt.......ttttttttt.......tttt...xxxxxxxxexxxexxx
tt".MM""NTTtttttttttttttttttttt....tttt.......ttt...ttttt.......xxxxx..exxxxeexx
tt""M""""Ttttttttttttttttttttttttttttttt...ttt..t..ttttttttxxxxx......xx.exx..xx
ttt""""TTTtttttttttttttttttttttttttttttttttttttt.tttttttxxxxxxxxxx....xxx.d.xxxx
tttttttttttttttttttttttttttttttttttttttttttttttttttttttttxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

################################################################################
# Zero! Nine! Eight!
#
NAME:     hangedman_slaughterboxes
TAGS:     no_pool_fixup no_monster_gen no_item_gen patrolling
ORIENT:   encompass
DEPTH:    D:16-26
MONS:     butterfly, plant
SUBVAULT: a : hm_sb_wall_set_up
KMASK:    a = no_trap_gen
KMASK:    xX' = !no_monster_gen
SHUFFLE:  de, fg, hi, jk, JK, nm, XZ / yz
SUBST:    X = xx', y= x'', Z = xx., z = x..
SUBST:    dfhk = x, egij = ., T = TTV, U = TUU, t : ttx, " : WW'
SUBST:    % = %%%%$$., * = ***%, | = |||*
SUBST:    JNQ = 0, OR = ., S : 09, M = 09, K = 9
MAP
   xxxxxxxxxxxxxxx      xxxxx       xxxx
  xxxxxxxxxxxxxxxxx    xxxxxxx    xxxxxxaaaaaaaaaaaaaaa
 xxxZZZZZZZZZZZZxxxxxxxxxXXXxxxxxxxxxZZaaaaaaaaaaaaaaaaa
xxxZ............ZxxxxxxXX'''XXxxxxxZZ..aaalalalalalalaaaa
xxZ..exdxexdxex..ZZXXXX'''x'''XXZZZ....aalllllllllllllaaaa
xxZ.ex........e....'''''''x''''''......aal%%%%*****|||laaa
xxZ.x..dxxxex.x....'x'''x'''x'''x...{..aal%........J8|llaa
xxZ.d.dx''''e.d...x'''x'''x'''x''.x..[.aal%.aKaa...aJ|laaa
xxZ.x.x'ede'x.x....'x'''x'''x'''x...(..aal%.K8aa.aa..*llaa
xxZ.e.x'd'd'x.e....''''''''''''''......aal%.aaa..aa..*laaa
xxZ.x.x'ede'x.x..aaaaaaaaaaaaaaaaaaaaaaaal%.aa.|.....*llaa
xxZ.d.e''''xd.d.aaaaaaaaaaaaaaaaaaaaaaaalaa.....|.aa.*laaa
xxZ.x.xexxxd..x.aa9...0aaa0..NOaalllllllaaaa.....aaa.%llaa
xxZ.e........xe.aa.aaa.aaa.aaaNaal%%%%%%aaana...aa8K.%laaa
xxZ.xexdxexdxe..aa.aaa.aaa.aaa.aal%90a...anana..aaKa.%llaa
xxZ.............aa.aaa.aaa.aaa.aal%0.a.0..anana......%laaa
xxxZ.......aaaaaaa....9aaa....0aal%aa......anaaa%%%%%%llaa
 xxxZ.....aaaaaaaaa.a.aaaaaaaaaaal%......<..aaaalllllllaaa
 xxxZ.jkj.aa9....aaaaaaa0aaaaaaaaaaaaaaaM....aalaaaaaaaaaa
  xxX'kXk'aa.aaa.aaaa....aaaaaaaaaaaaaaaa..0.%laaaaaaaaaaxx
  xxX'jkj'aa.aaa.aaaaaa..a...QRaaa.....aa....%laa.......Zxx
  xxX'''''aa.aaa.aa.aaa.%a.aaaQaaa.]1U.aa..aa%laa..)....Zxx
  xxX'''''aa....9aa.aaa0%a.aaa.aaa.1G1.aa.a.0%laa.>.>..Zxxx
  xxX'kjk'aaaaaaaaa...08*a.aaa.aaa.U1}.aa.a09%laa......Zxx
  xxX'jXj'aaaaaaaa0..%%*aa9....aaa.....aa%%%%%laa..x..Zxxx
 xxxX'kjk'aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaallllllaa.....Xxx
 xxX''''''aa....0aaa....0aaa...aaaaaaaaaaaaaaaaaa'x'x'Xxx
 xxX''''''aa.aaa.aaa.aaa.aSa.a.aaaaaaaaaaaaaaaaaa'''''Xxx
 xxX'jkj''aa.aaa.aaa.aaa.a..aaa..a...QRaaa0..NOaa''x''Xxx
 xxX'kXk''aa.aaa.aaa.aaa.a.aaaaa.a.aaaQaaa.aaaNaa''''''Xxx
 xxX'jkj''aa9....aaa0....a%0aaa..a.aaa.aaa.aaa.aa'x'x''Xxxx
 xxX''''''aaaaaaaaaaaaaaaa*80a.aaa.aaa.aaa.aaa.aa'''''''Xxx
 xxX''''''aaaaaaaaaaaaaaaa|*%..Saa9....aaa....0aa''x'xx'Xxx
 xxX'kjk''aawwwwwwaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa'''''''Xxx
 xxX'jXj''aaw2112waa....Maaa....0aa*%%..0aaaaaaaa'x'x''Xxxx
 xxX'kjk''aaw..T.Waa.aaa.aaa.aaa.a*80...aaaaaaaaa''''''Xxx
 xxxX'''''aaw....Waa.aaa.aaa.aaa.a%0aaa.aa9...0aa''x''Xxx
  xxX'''''aaw.2..Waa.aaa.aaa.aaa.a%.aaa.aa.aaa.aa'''''Xxx
  xxX'jkj'aaw....Waa.....aaa0....a..aaaaaa.aaa.aa'x'x'Xxx
  xxX'kXk'aaw...Gwaaaaaaaaaaaaaaaa....aaaa.aaa.aa'''''Xxx
  xxX'jkj'aaw.C..wwaaaaaaaaaaaaaaa0aaaaaaa....9aa..x..Zxxx
  xxX'''''aaw....GwwWWWWwwaaaaaaaaaaaaaaaaaaaaaaa.....Zxxxx
  xxX'''''aaW......G....2waa....0aaa9....aaaaaaa.......Zxxx
  xxX'kjk'aaW..C.......T1waa.aaa.aaa.aaa.aa.............Zxx
  xxZ'jXj'aaW.....C..2..1waa.aaa.aaa.aaa.aa..fxgxfxgxfx.Zxx
 xxxZ.kjk.aaw...........2waa.aaa.aaa.aaa.aa.fx........f.Zxx
xxxZ.......aawWWWwwwwwwwwwaa9....aaa....9aa.x..gxxxfx.x.Zxx
xxZ''''t'..aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa.g.gx''''f.g.Zxx
xxX''''''....aaaaaaaaaaaaaaaaaaaaaaaaaaaaa..x.x'fgf'x.x.Zxx
xxX''''''t....''''''''''''''''''''''''''....f.x'g'g'x.f.Zxx
xxX't'<'''''.hih''ihi''''''''''''hih''ihi...x.x'fgf'x.x.Zxx
xxX'''""'''t.iXi''hXh''hih''ihi''iXi''hXh...g.f''''xg.x.Zxx
xxX'''""<'''.hih''ihi''iXi''hXh''hih''ihi...x.xfxxxg..x.Zxx
xxX''<''''''..'''''''''hih''ihi'''''''''....f........xf.Zxx
xxX'''''t'''ZZZXXXXXXX''''''''''XXXXXXXXZZ..xfxgxfxgxf..Zxx
xxX''''''''ZxxxxxxxxxxXXXXXXXXXXxxxxxxxxxxZ............Zxxx
xxxXXXXXXXXxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxZZZZZZZZZZZZxxx
 xxxxxxxxxxxx        xxxxxxxxxxxxx       xxxxxxxxxxxxxxxx
  xxxxxxxxxx                              xxxxxxxxxxxxxx
ENDMAP

# Subvault which is purely an isolated set-up for hangedman_slaughterboxes.
NAME:    hangedman_sb_wall_set_up
DEPTH:
ORIENT:  encompass
TAGS:    hm_sb_wall_set_up no_monster_gen no_trap_gen allow_dup
: if you.absdepth() > 20 then
SHUFFLE:  cbv
: end
SHUFFLE: ABCDE / BADCE / AGHIC / ACGHE, JKLMN / KJMLN / JPQRL / JLPQN
SHUFFLE: STUVW / TSVUW / SYZaU / SUYZW, defgh / edgfh / djklf / dfjkh
SHUFFLE: mnopq / nmpoq / mstuo / mostq, BDF, KMO, TVX, egi, npr
SUBST:   ACFJLOSUXdfimor = ., BDGHIKMPQRTVYZaegjklnpstu = x
SUBST:   E : x., N : x., W : x., h : x., q : x.
MAP
                              ccccccccccccccc
                             ccccccccccccccccc
                             ccc c c c c c cccc
                             cc             cccc
                             cc              ccc
                             cc               cc
                             cc   c cc   c   ccc
                             cc     cc cc     cc
                             cc   ccc  cc    ccc
       cccccccccccccccccccccccc   cc          cc
      cccchcccccccqccccccccccc cc       cc   ccc
      cc     .c.     cc       ccc+     ccc    cc
      cc def c+c mno cc       cc. +   cc     ccc
      ch ghg .c. pqp qc    c   + . +  cc c    cc
      cc fed c+c onm cc    c    + . +        ccc
 ccccccc     .c.     cc  cc      + .cc        cc
ccccNcccc.c.cccc.c.c.cc           +ccc       ccc
cc     ccc+c+c cc+c+cccccc+c+c     cc cccccccccc
cc JKL .ccc    c.c.c.cccc.c.ccc      cccccccccc
cN MNM c+cSTU  c     .c.     c+      cc
cc LKJ .c VWV  c def c+c     .c  cc  cc
cc     c+ UTS  c ghg .c.     c+ c    cc
cc.c.c.cc      c fed c+c     .c c    cc
ccc+c+cc      cc     .c.     cc      cc
cc.c.c.cccccccc+ccccccc..c.c.cc      cc
cc     .c.     ccc   +.cc+c+ccccccccccc
cc ABC c+c JKL c c c c+c.c.c.cccccqcccc
cE DED .c. MNM c  UVS  c     .c.     cc
cc CBA c+c LKJ c cTWVc c dgf c+c mpo cc
cc     .c.     c  STU  c ehe .c. nqn qc
ccccEccccc.c.c.c   c ccc fgd c+c opm cc
ccccccccccc+c+cc      cc     .c.     cc
cc      cc.c.c.cccccccc+cccccccc.c.c.cc
cc      cc     .c.     cc      cc+c+ccc
cc      c. DCB c+c JML c      cc.c.c.cc
cc      +c AEC .c. KNK c  SVU +c     cc
cc      c. BAD c+c LMJ c  TWT c. dgf cc
cc      +c     .c.     c  UVSc+c ehe hc
cc      ccc.c.cccc.c.c.c    ccc. fgd cc
cc       c+c+cccccc+c+cc c+c+ccc     cc
cc              cc.c.c.cccc.c.cccchcccc
.c              cc     .c.     ccccccc
.+              cc ADC c+c JML cc
.+              cE BEB .c. KNK Nc
.c              cc CDA c+c LMJ cc
 cc             cc     .c.     cc
 ccc++ccccccccccccccEcccccccNcccc
   ....cccccccccccccccccccccccccc
ENDMAP
