// ZZ> This item is goes away when picked up, Runs end conditions
IfSpawned
  SetTurnModeToSpin
  DisableExport
IfTimeOut
  // Make sparklies
  SpawnPoof
  tmpargument = 10
  SetTime
IfGrabbed
  EnableExport
  BeatModule
  tmpargument = 0
  PlayFullSound
  StopMusic

  SetTargetToWhoeverIsHolding
  tmpargument = 0
  SendMessageNear

  tmpargument = 100
  tmpdistance = EXPSECRET
  GiveExperienceToTarget

  tmpargument = 300
  tmpdistance = EXPQUEST
  GiveExperienceToTargetTeam

  // Set the end text
  ClearEndMessage
  tmpargument = 1
  AddEndMessage
  tmpargument = 2
  AddEndMessage

  // Mark this module as beaten, hidden modules may open up
  tmpargument = [MAIN]
  tmpdistance = 3           //The quest level
  AddQuestAllPlayers        //Add it
  
  //This unlocks the ash domain
  tmpargument = [BEAT]
  AddIDSZ
  
  // Become the export object
  SetTargetToSelf
  tmpargument = 117
  ChangeTargetClass
  
End					// All done
