Mojo::ByteStream(3)

NAME
Mojo::ByteStream - ByteStream

SYNOPSIS
  use Mojo::ByteStream;

  # Manipulate bytestream
  my $stream = Mojo::ByteStream->new('foo_bar_baz');
  say $stream->camelize;

  # Chain methods
  my $stream = Mojo::ByteStream->new('foo bar baz')->quote;
  $stream = $stream->unquote->encode('UTF-8')->b64_encode('');
  say "$stream";

  # Use the alternative constructor
  use Mojo::ByteStream 'b';
  my $stream = b('foobarbaz')->b64_encode('')->say;

DESCRIPTION
Mojo::ByteStream provides a more friendly API for the bytestream manipulation functions in Mojo::Util.

FUNCTIONS
Mojo::ByteStream implements the following functions.

  b
  my $stream = b('test123');

Construct a new scalar-based Mojo::ByteStream object.

METHODS
Mojo::ByteStream implements the following methods.

  new
  my $stream = Mojo::ByteStream->new('test123');

Construct a new scalar-based Mojo::ByteStream object.

  b64_decode
  $stream = $stream->b64_decode;

Base64 decode bytestream with "b64_decode" in Mojo::Util.

  b64_encode
  $stream = $stream->b64_encode;
  $stream = $stream->b64_encode("\n");

Base64 encode bytestream with "b64_encode" in Mojo::Util.

  b('foo bar baz')->b64_encode('')->say;

  camelize
  $stream = $stream->camelize;

Camelize bytestream with "camelize" in Mojo::Util.

  clone
  my $stream2 = $stream->clone;

Clone bytestream.

  decamelize
  $stream = $stream->decamelize;

Decamelize bytestream with "decamelize" in Mojo::Util.

  decode
  $stream = $stream->decode;
  $stream = $stream->decode('iso-8859-1');

Decode bytestream with "decode" in Mojo::Util, defaults to "UTF-8".

  $stream->decode('UTF-16LE')->unquote->trim->say;

  encode
  $stream = $stream->encode;
  $stream = $stream->encode('iso-8859-1');

Encode bytestream with "encode" in Mojo::Util, defaults to "UTF-8".

  $stream->trim->quote->encode->say;

  hmac_sha1_sum
  $stream = $stream->hmac_sha1_sum('passw0rd');

Generate HMAC-SHA1 checksum for bytestream with "hmac_sha1_sum" in Mojo::Util.

  b('foo bar baz')->hmac_sha1_sum('secr3t')->quote->say;

  html_unescape
  $stream = $stream->html_unescape;

Unescape all HTML entities in bytestream with "html_unescape" in Mojo::Util.

  b('&lt;html&gt;')->html_unescape->url_escape->say;

  md5_bytes
  $stream = $stream->md5_bytes;

Generate binary MD5 checksum for bytestream with "md5_bytes" in Mojo::Util.

  md5_sum
  $stream = $stream->md5_sum;

Generate MD5 checksum for bytestream with "md5_sum" in Mojo::Util.

  punycode_decode
  $stream = $stream->punycode_decode;

Punycode decode bytestream with "punycode_decode" in Mojo::Util.

  punycode_encode
  $stream = $stream->punycode_encode;

Punycode encode bytestream with "punycode_encode" in Mojo::Util.

  quote
  $stream = $stream->quote;

Quote bytestream with "quote" in Mojo::Util.

  say
  $stream->say;
  $stream->say(*STDERR);

Print bytestream to handle and append a newline, defaults to "STDOUT".

  secure_compare
  my $bool = $stream->secure_compare($str);

Compare bytestream with "secure_compare" in Mojo::Util.

  say 'Match!' if b('foo')->secure_compare('foo');

  sha1_bytes
  $stream = $stream->sha1_bytes;

Generate binary SHA1 checksum for bytestream with "sha1_bytes" in Mojo::Util.

  sha1_sum
  $stream = $stream->sha1_sum;

Generate SHA1 checksum for bytestream with "sha1_sum" in Mojo::Util.

  size
  my $size = $stream->size;

Size of bytestream.

  slurp
  $stream = $stream->slurp;

Read all data at once from file into bytestream with "slurp" in Mojo::Util.

  b('/home/sri/myapp.pl')->slurp->split("\n")->shuffle->join("\n")->say;

  spurt
  $stream = $stream->spurt('/home/sri/myapp.pl');

Write all data from bytestream at once to file with "spurt" in Mojo::Util.

  b('/home/sri/foo.txt')->slurp->squish->spurt('/home/sri/bar.txt');

  split
  my $collection = $stream->split(',');

Turn bytestream into Mojo::Collection object containing Mojo::ByteStream objects.

  b('a,b,c')->split(',')->quote->join(',')->say;

  squish
  $stream = $stream->squish;

Trim whitespace characters from both ends of bytestream and then change all consecutive groups of whitespace into one space each with "squish" in Mojo::Util.

  tap
  $stream = $stream->tap(sub {...});

Alias for "tap" in Mojo::Base.

  to_string
  my $str = $stream->to_string;
  my $str = "$stream";

Stringify bytestream.

  trim
  $stream = $stream->trim;

Trim whitespace characters from both ends of bytestream with "trim" in Mojo::Util.

  unquote
  $stream = $stream->unquote;

Unquote bytestream with "unquote" in Mojo::Util.

  url_escape
  $stream = $stream->url_escape;
  $stream = $stream->url_escape('^A-Za-z0-9\-._~');

Percent encode all unsafe characters in bytestream with "url_escape" in Mojo::Util.

  b('foo bar baz')->url_escape->say;

  url_unescape
  $stream = $stream->url_unescape;

Decode percent encoded characters in bytestream with "url_unescape" in Mojo::Util.

  b('%3Chtml%3E')->url_unescape->xml_escape->say;

  xml_escape
  $stream = $stream->xml_escape;

Escape only the characters "&", "<", ">", """ and "'" in bytestream with "xml_escape" in Mojo::Util.

  xor_encode
  $stream = $stream->xor_encode($key);

XOR encode bytestream with "xor_encode" in Mojo::Util.

BYTESTREAM
Direct scalar reference access to the bytestream is also possible.

  $$stream .= 'foo';

SEE ALSO
Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.