NASM Manual

# The Netwide Assembler: NASM

Next Chapter | Previous Chapter | Contents | Index

## Chapter 4: The NASM Preprocessor

NASM contains a powerful macro processor, which supports conditional assembly, multi-level file inclusion, two forms of macro (single-line and multi-line), and a `context stack' mechanism for extra macro power. Preprocessor directives all begin with a `%` sign.

The preprocessor collapses all lines which end with a backslash (\) character into a single line. Thus:

    %define THIS_VERY_LONG_MACRO_NAME_IS_DEFINED_TO \
            THIS_VALUE

will work like a single-line macro without the backslash-newline sequence.

### 4.1 Single-Line Macros

#### 4.1.1 The Normal Way: `%define`

Single-line macros are defined using the `%define` preprocessor directive. The definitions work in a similar way to C; so you can do things like

    %define ctrl    0x1F &
    %define param(a,b) ((a)+(a)*(b))

            mov     byte [param(2,ebx)], ctrl 'D'

which will expand to

            mov     byte [(2)+(2)*(ebx)], 0x1F & 'D'

When the expansion of a single-line macro contains tokens which invoke another macro, the expansion is performed at invocation time, not at definition time. Thus the code

    %define a(x)    1+b(x)
    %define b(x)    2*x

            mov     ax,a(8)

will evaluate in the expected way to `mov ax,1+2*8`, even though the macro `b` wasn't defined at the time of definition of `a`.

Macros defined with `%define` are case sensitive: after `%define foo bar`, only `foo` will expand to `bar`: `Foo` or `FOO` will not. By using `%idefine` instead of `%define` (the `i' stands for `insensitive') you can define all the case variants of a macro at once, so that `%idefine foo bar` would cause `foo`, `Foo`, `FOO`, `fOO` and so on all to expand to `bar`.

There is a mechanism which detects when a macro call has occurred as a result of a previous expansion of the same macro, to guard against circular references and infinite loops. If this happens, the preprocessor will only expand the first occurrence of the macro. Hence, if you code

    %define a(x)    1+a(x)

            mov     ax,a(3)

the macro `a(3)` will expand once, becoming `1+a(3)`, and will then expand no further. This behaviour can be useful: see section 9.1 for an example of its use.

You can overload single-line macros: if you write

    %define foo(x)   1+x
    %define foo(x,y) 1+x*y

the preprocessor will be able to handle both types of macro call, by counting the parameters you pass; so `foo(3)` will become `1+3` whereas `foo(ebx,2)` will become `1+ebx*2`. However, if you define

    %define foo bar

then no other definition of `foo` will be accepted: a macro with no parameters prohibits the definition of the same name as a macro with parameters, and vice versa.

This doesn't prevent single-line macros being redefined: you can perfectly well define a macro with

    %define foo bar

and then re-define it later in the same source file with

    %define foo baz

Then everywhere the macro `foo` is invoked, it will be expanded according to the most recent definition. This is particularly useful when defining single-line macros with `%assign` (see section 4.1.7).

You can pre-define single-line macros using the `-d' option on the NASM command line: see section 2.1.18.

#### 4.1.2 Resolving `%define`: `%xdefine`

To have a reference to an embedded single-line macro resolved at the time that the embedding macro is defined, as opposed to when the embedding macro is expanded, you need a different mechanism to the one offered by `%define`. The solution is to use `%xdefine`, or it's case-insensitive counterpart `%ixdefine`.

Suppose you have the following code:

    %define  isTrue  1
    %define  isFalse isTrue
    %define  isTrue  0

    val1:    db      isFalse

    %define  isTrue  1

    val2:    db      isFalse

In this case, `val1` is equal to 0, and `val2` is equal to 1. This is because, when a single-line macro is defined using `%define`, it is expanded only when it is called. As `isFalse` expands to `isTrue`, the expansion will be the current value of `isTrue`. The first time it is called that is 0, and the second time it is 1.

If you wanted `isFalse` to expand to the value assigned to the embedded macro `isTrue` at the time that `isFalse` was defined, you need to change the above code to use `%xdefine`.

    %xdefine isTrue  1
    %xdefine isFalse isTrue
    %xdefine isTrue  0

    val1:    db      isFalse

    %xdefine isTrue  1

    val2:    db      isFalse

Now, each time that `isFalse` is called, it expands to 1, as that is what the embedded macro `isTrue` expanded to at the time that `isFalse` was defined.

#### 4.1.3 Macro Indirection: `%[...]`

The `%[...]` construct can be used to expand macros in contexts where macro expansion would otherwise not occur, including in the names other macros. For example, if you have a set of macros named `Foo16`, `Foo32` and `Foo64`, you could write:

         mov ax,Foo%[__BITS__]   ; The Foo value

to use the builtin macro `__BITS__` (see section 4.11.5) to automatically select between them. Similarly, the two statements:

    %xdefine Bar         Quux    ; Expands due to %xdefine
    %define  Bar         %[Quux] ; Expands due to %[...]

have, in fact, exactly the same effect.

`%[...]` concatenates to adjacent tokens in the same way that multi-line macro parameters do, see section 4.3.7 for details.

#### 4.1.4 Concatenating Single Line Macro Tokens: `%+`

Individual tokens in single line macros can be concatenated, to produce longer tokens for later processing. This can be useful if there are several similar macros that perform similar functions.

Please note that a space is required after `%+`, in order to disambiguate it from the syntax `%+1` used in multiline macros.

As an example, consider the following:

    %define BDASTART 400h                ; Start of BIOS data area

    struc   tBIOSDA                      ; its structure
            .COM1addr       RESW    1
            .COM2addr       RESW    1
            ; ..and so on
    endstruc

Now, if we need to access the elements of tBIOSDA in different places, we can end up with:

            mov     ax,BDASTART + tBIOSDA.COM1addr
            mov     bx,BDASTART + tBIOSDA.COM2addr

This will become pretty ugly (and tedious) if used in many places, and can be reduced in size significantly by using the following macro:

    ; Macro to access BIOS variables by their names (from tBDA):

    %define BDA(x)  BDASTART + tBIOSDA. %+ x

Now the above code can be written as:

            mov     ax,BDA(COM1addr)
            mov     bx,BDA(COM2addr)

Using this feature, we can simplify references to a lot of macros (and, in turn, reduce typing errors).

#### 4.1.5 The Macro Name Itself: `%?` and `%??`

The special symbols `%?` and `%??` can be used to reference the macro name itself inside a macro expansion, this is supported for both single-and multi-line macros. `%?` refers to the macro name as invoked, whereas `%??` refers to the macro name as declared. The two are always the same for case-sensitive macros, but for case-insensitive macros, they can differ.

For example:

    %idefine Foo mov %?,%??

            foo
            FOO

will expand to:

            mov foo,Foo
            mov FOO,Foo

The sequence:

    %idefine keyword $%?

can be used to make a keyword "disappear", for example in case a new instruction has been used as a label in older code. For example:

    %idefine pause $%?                  ; Hide the PAUSE instruction

#### 4.1.6 Undefining Single-Line Macros: `%undef`

Single-line macros can be removed with the `%undef` directive. For example, the following sequence:

    %define foo bar
    %undef  foo

            mov     eax, foo

will expand to the instruction `mov eax, foo`, since after `%undef` the macro `foo` is no longer defined.

Macros that would otherwise be pre-defined can be undefined on the command-line using the `-u' option on the NASM command line: see section 2.1.19.

#### 4.1.7 Preprocessor Variables: `%assign`

An alternative way to define single-line macros is by means of the `%assign` command (and its case-insensitive counterpart `%iassign`, which differs from `%assign` in exactly the same way that `%idefine` differs from `%define`).

`%assign` is used to define single-line macros which take no parameters and have a numeric value. This value can be specified in the form of an expression, and it will be evaluated once, when the `%assign` directive is processed.

Like `%define`, macros defined using `%assign` can be re-defined later, so you can do things like

    %assign i i+1

to increment the numeric value of a macro.

`%assign` is useful for controlling the termination of `%rep` preprocessor loops: see section 4.5 for an example of this. Another use for `%assign` is given in section 8.4 and section 9.1.

The expression passed to `%assign` is a critical expression (see section 3.8), and must also evaluate to a pure number (rather than a relocatable reference such as a code or data address, or anything involving a register).

#### 4.1.8 Defining Strings: `%defstr`

`%defstr`, and its case-insensitive counterpart `%idefstr`, define or redefine a single-line macro without parameters but converts the entire right-hand side, after macro expansion, to a quoted string before definition.

For example:

    %defstr test TEST

is equivalent to

    %define test 'TEST'

This can be used, for example, with the `%!` construct (see section 4.10.2):

    %defstr PATH %!PATH          ; The operating system PATH variable

#### 4.1.9 Defining Tokens: `%deftok`

`%deftok`, and its case-insensitive counterpart `%ideftok`, define or redefine a single-line macro without parameters but converts the second parameter, after string conversion, to a sequence of tokens.

For example:

    %deftok test 'TEST'

is equivalent to

    %define test TEST

### 4.2 String Manipulation in Macros

It's often useful to be able to handle strings in macros. NASM supports a few simple string handling macro operators from which more complex operations can be constructed.

All the string operators define or redefine a value (either a string or a numeric value) to a single-line macro. When producing a string value, it may change the style of quoting of the input string or strings, and possibly use `\`-escapes inside ```-quoted strings.

#### 4.2.1 Concatenating Strings: `%strcat`

The `%strcat` operator concatenates quoted strings and assign them to a single-line macro.

For example:

    %strcat alpha "Alpha: ", '12" screen'

... would assign the value `'Alpha: 12" screen'` to `alpha`. Similarly:

    %strcat beta '"foo"\', "'bar'"

... would assign the value ``"foo"\\'bar'`` to `beta`.

The use of commas to separate strings is permitted but optional.

#### 4.2.2 String Length: `%strlen`

The `%strlen` operator assigns the length of a string to a macro. For example:

    %strlen charcnt 'my string'

In this example, `charcnt` would receive the value 9, just as if an `%assign` had been used. In this example, `'my string'` was a literal string but it could also have been a single-line macro that expands to a string, as in the following example:

    %define sometext 'my string'
    %strlen charcnt sometext

As in the first case, this would result in `charcnt` being assigned the value of 9.

#### 4.2.3 Extracting Substrings: `%substr`

Individual letters or substrings in strings can be extracted using the `%substr` operator. An example of its use is probably more useful than the description:

    %substr mychar 'xyzw' 1       ; equivalent to %define mychar 'x'
    %substr mychar 'xyzw' 2       ; equivalent to %define mychar 'y'
    %substr mychar 'xyzw' 3       ; equivalent to %define mychar 'z'
    %substr mychar 'xyzw' 2,2     ; equivalent to %define mychar 'yz'
    %substr mychar 'xyzw' 2,-1    ; equivalent to %define mychar 'yzw'
    %substr mychar 'xyzw' 2,-2    ; equivalent to %define mychar 'yz'

As with `%strlen` (see section 4.2.2), the first parameter is the single-line macro to be created and the second is the string. The third parameter specifies the first character to be selected, and the optional fourth parameter preceeded by comma) is the length. Note that the first index is 1, not 0 and the last index is equal to the value that `%strlen` would assign given the same string. Index values out of range result in an empty string. A negative length means "until N-1 characters before the end of string", i.e. `-1` means until end of string, `-2` until one character before, etc.

### 4.3 Multi-Line Macros: `%macro`

Multi-line macros are much more like the type of macro seen in MASM and TASM: a multi-line macro definition in NASM looks something like this.

    %macro  prologue 1

            push    ebp
            mov     ebp,esp
            sub     esp,%1

    %endmacro

This defines a C-like function prologue as a macro: so you would invoke the macro with a call such as

    myfunc:   prologue 12

which would expand to the three lines of code

    myfunc: push    ebp
            mov     ebp,esp
            sub     esp,12

The number `1` after the macro name in the `%macro` line defines the number of parameters the macro `prologue` expects to receive. The use of `%1` inside the macro definition refers to the first parameter to the macro call. With a macro taking more than one parameter, subsequent parameters would be referred to as `%2`, `%3` and so on.

Multi-line macros, like single-line macros, are case-sensitive, unless you define them using the alternative directive `%imacro`.

If you need to pass a comma as part of a parameter to a multi-line macro, you can do that by enclosing the entire parameter in braces. So you could code things like

    %macro  silly 2

        %2: db      %1

    %endmacro

            silly 'a', letter_a             ; letter_a:  db 'a'
            silly 'ab', string_ab           ; string_ab: db 'ab'
            silly {13,10}, crlf             ; crlf:      db 13,10

#### 4.3.1 Overloading Multi-Line Macros

As with single-line macros, multi-line macros can be overloaded by defining the same macro name several times with different numbers of parameters. This time, no exception is made for macros with no parameters at all. So you could define

    %macro  prologue 0

            push    ebp
            mov     ebp,esp

    %endmacro

to define an alternative form of the function prologue which allocates no local stack space.

Sometimes, however, you might want to `overload' a machine instruction; for example, you might want to define

    %macro  push 2

            push    %1
            push    %2

    %endmacro

so that you could code

            push    ebx             ; this line is not a macro call
            push    eax,ecx         ; but this one is

Ordinarily, NASM will give a warning for the first of the above two lines, since `push` is now defined to be a macro, and is being invoked with a number of parameters for which no definition has been given. The correct code will still be generated, but the assembler will give a warning. This warning can be disabled by the use of the `-w-macro-params` command-line option (see section 2.1.24).

#### 4.3.2 Macro-Local Labels

NASM allows you to define labels within a multi-line macro definition in such a way as to make them local to the macro call: so calling the same macro multiple times will use a different label each time. You do this by prefixing `%%` to the label name. So you can invent an instruction which executes a `RET` if the `Z` flag is set by doing this:

    %macro  retz 0

            jnz     %%skip
            ret
        %%skip:

    %endmacro

You can call this macro as many times as you want, and every time you call it NASM will make up a different `real' name to substitute for the label `%%skip`. The names NASM invents are of the form `..@2345.skip`, where the number 2345 changes with every macro call. The `..@` prefix prevents macro-local labels from interfering with the local label mechanism, as described in section 3.9. You should avoid defining your own labels in this form (the `..@` prefix, then a number, then another period) in case they interfere with macro-local labels.

#### 4.3.3 Greedy Macro Parameters

Occasionally it is useful to define a macro which lumps its entire command line into one parameter definition, possibly after extracting one or two smaller parameters from the front. An example might be a macro to write a text string to a file in MS-DOS, where you might want to be able to write

            writefile [filehandle],"hello, world",13,10

NASM allows you to define the last parameter of a macro to be greedy, meaning that if you invoke the macro with more parameters than it expects, all the spare parameters get lumped into the last defined one along with the separating commas. So if you code:

    %macro  writefile 2+

            jmp     %%endstr
      %%str:        db      %2
      %%endstr:
            mov     dx,%%str
            mov     cx,%%endstr-%%str
            mov     bx,%1
            mov     ah,0x40
            int     0x21

    %endmacro

then the example call to `writefile` above will work as expected: the text before the first comma, `[filehandle]`, is used as the first macro parameter and expanded when `%1` is referred to, and all the subsequent text is lumped into `%2` and placed after the `db`.

The greedy nature of the macro is indicated to NASM by the use of the `+` sign after the parameter count on the `%macro` line.

If you define a greedy macro, you are effectively telling NASM how it should expand the macro given any number of parameters from the actual number specified up to infinity; in this case, for example, NASM now knows what to do when it sees a call to `writefile` with 2, 3, 4 or more parameters. NASM will take this into account when overloading macros, and will not allow you to define another form of `writefile` taking 4 parameters (for example).

Of course, the above macro could have been implemented as a non-greedy macro, in which case the call to it would have had to look like

              writefile [filehandle], {"hello, world",13,10}

NASM provides both mechanisms for putting commas in macro parameters, and you choose which one you prefer for each macro definition.

See section 6.3.1 for a better way to write the above macro.

#### 4.3.4 Default Macro Parameters

NASM also allows you to define a multi-line macro with a range of allowable parameter counts. If you do this, you can specify defaults for omitted parameters. So, for example:

    %macro  die 0-1 "Painful program death has occurred."

            writefile 2,%1
            mov     ax,0x4c01
            int     0x21

    %endmacro

This macro (which makes use of the `writefile` macro defined in section 4.3.3) can be called with an explicit error message, which it will display on the error output stream before exiting, or it can be called with no parameters, in which case it will use the default error message supplied in the macro definition.

In general, you supply a minimum and maximum number of parameters for a macro of this type; the minimum number of parameters are then required in the macro call, and then you provide defaults for the optional ones. So if a macro definition began with the line

    %macro foobar 1-3 eax,[ebx+2]

then it could be called with between one and three parameters, and `%1` would always be taken from the macro call. `%2`, if not specified by the macro call, would default to `eax`, and `%3` if not specified would default to `[ebx+2]`.

You can provide extra information to a macro by providing too many default parameters:

    %macro quux 1 something

This will trigger a warning by default; see section 2.1.24 for more information. When `quux` is invoked, it receives not one but two parameters. `something` can be referred to as `%2`. The difference between passing `something` this way and writing `something` in the macro body is that with this way `something` is evaluated when the macro is defined, not when it is expanded.

You may omit parameter defaults from the macro definition, in which case the parameter default is taken to be blank. This can be useful for macros which can take a variable number of parameters, since the `%0` token (see section 4.3.5) allows you to determine how many parameters were really passed to the macro call.

This defaulting mechanism can be combined with the greedy-parameter mechanism; so the `die` macro above could be made more powerful, and more useful, by changing the first line of the definition to

    %macro die 0-1+ "Painful program death has occurred.",13,10

The maximum parameter count can be infinite, denoted by `*`. In this case, of course, it is impossible to provide a full set of default parameters. Examples of this usage are shown in section 4.3.6.

#### 4.3.5 `%0`: Macro Parameter Counter

The parameter reference `%0` will return a numeric constant giving the number of parameters received, that is, if `%0` is n then `%`n is the last parameter. `%0` is mostly useful for macros that can take a variable number of parameters. It can be used as an argument to `%rep` (see section 4.5) in order to iterate through all the parameters of a macro. Examples are given in section 4.3.6.

#### 4.3.6 `%rotate`: Rotating Macro Parameters

Unix shell programmers will be familiar with the `shift` shell command, which allows the arguments passed to a shell script (referenced as `$1`, `$2` and so on) to be moved left by one place, so that the argument previously referenced as `$2` becomes available as `$1`, and the argument previously referenced as `$1` is no longer available at all.

NASM provides a similar mechanism, in the form of `%rotate`. As its name suggests, it differs from the Unix `shift` in that no parameters are lost: parameters rotated off the left end of the argument list reappear on the right, and vice versa.

`%rotate` is invoked with a single numeric argument (which may be an expression). The macro parameters are rotated to the left by that many places. If the argument to `%rotate` is negative, the macro parameters are rotated to the right.

So a pair of macros to save and restore a set of registers might work as follows:

    %macro  multipush 1-*

      %rep  %0
            push    %1
      %rotate 1
      %endrep

    %endmacro

This macro invokes the `PUSH` instruction on each of its arguments in turn, from left to right. It begins by pushing its first argument, `%1`, then invokes `%rotate` to move all the arguments one place to the left, so that the original second argument is now available as `%1`. Repeating this procedure as many times as there were arguments (achieved by supplying `%0` as the argument to `%rep`) causes each argument in turn to be pushed.

Note also the use of `*` as the maximum parameter count, indicating that there is no upper limit on the number of parameters you may supply to the `multipush` macro.

It would be convenient, when using this macro, to have a `POP` equivalent, which didn't require the arguments to be given in reverse order. Ideally, you would write the `multipush` macro call, then cut-and-paste the line to where the pop needed to be done, and change the name of the called macro to `multipop`, and the macro would take care of popping the registers in the opposite order from the one in which they were pushed.

This can be done by the following definition:

    %macro  multipop 1-*

      %rep %0
      %rotate -1
            pop     %1
      %endrep

    %endmacro

This macro begins by rotating its arguments one place to the right, so that the original last argument appears as `%1`. This is then popped, and the arguments are rotated right again, so the second-to-last argument becomes `%1`. Thus the arguments are iterated through in reverse order.

#### 4.3.7 Concatenating Macro Parameters

NASM can concatenate macro parameters and macro indirection constructs on to other text surrounding them. This allows you to declare a family of symbols, for example, in a macro definition. If, for example, you wanted to generate a table of key codes along with offsets into the table, you could code something like

    %macro keytab_entry 2

        keypos%1    equ     $-keytab
                    db      %2

    %endmacro

    keytab:
              keytab_entry F1,128+1
              keytab_entry F2,128+2
              keytab_entry Return,13

which would expand to

    keytab:
    keyposF1        equ     $-keytab
                    db     128+1
    keyposF2        equ     $-keytab
                    db      128+2
    keyposReturn    equ     $-keytab
                    db      13

You can just as easily concatenate text on to the other end of a macro parameter, by writing `%1foo`.

If you need to append a digit to a macro parameter, for example defining labels `foo1` and `foo2` when passed the parameter `foo`, you can't code `%11` because that would be taken as the eleventh macro parameter. Instead, you must code `%{1}1`, which will separate the first `1` (giving the number of the macro parameter) from the second (literal text to be concatenated to the parameter).

This concatenation can also be applied to other preprocessor in-line objects, such as macro-local labels (section 4.3.2) and context-local labels (section 4.7.2). In all cases, ambiguities in syntax can be resolved by enclosing everything after the `%` sign and before the literal text in braces: so `%{%foo}bar` concatenates the text `bar` to the end of the real name of the macro-local label `%%foo`. (This is unnecessary, since the form NASM uses for the real names of macro-local labels means that the two usages `%{%foo}bar` and `%%foobar` would both expand to the same thing anyway; nevertheless, the capability is there.)

The single-line macro indirection construct, `%[...]` (section 4.1.3), behaves the same way as macro parameters for the purpose of concatenation.

See also the `%+` operator, section 4.1.4.

#### 4.3.8 Condition Codes as Macro Parameters

NASM can give special treatment to a macro parameter which contains a condition code. For a start, you can refer to the macro parameter `%1` by means of the alternative syntax `%+1`, which informs NASM that this macro parameter is supposed to contain a condition code, and will cause the preprocessor to report an error message if the macro is called with a parameter which is not a valid condition code.

Far more usefully, though, you can refer to the macro parameter by means of `%-1`, which NASM will expand as the inverse condition code. So the `retz` macro defined in section 4.3.2 can be replaced by a general conditional-return macro like this:

    %macro  retc 1

            j%-1    %%skip
            ret
      %%skip:

    %endmacro

This macro can now be invoked using calls like `retc ne`, which will cause the conditional-jump instruction in the macro expansion to come out as `JE`, or `retc po` which will make the jump a `JPE`.

The `%+1` macro-parameter reference is quite happy to interpret the arguments `CXZ` and `ECXZ` as valid condition codes; however, `%-1` will report an error if passed either of these, because no inverse condition code exists.

#### 4.3.9 Disabling Listing Expansion

When NASM is generating a listing file from your program, it will generally expand multi-line macros by means of writing the macro call and then listing each line of the expansion. This allows you to see which instructions in the macro expansion are generating what code; however, for some macros this clutters the listing up unnecessarily.

NASM therefore provides the `.nolist` qualifier, which you can include in a macro definition to inhibit the expansion of the macro in the listing file. The `.nolist` qualifier comes directly after the number of parameters, like this:

    %macro foo 1.nolist

Or like this:

    %macro bar 1-5+.nolist a,b,c,d,e,f,g,h

#### 4.3.10 Undefining Multi-Line Macros: `%unmacro`

Multi-line macros can be removed with the `%unmacro` directive. Unlike the `%undef` directive, however, `%unmacro` takes an argument specification, and will only remove exact matches with that argument specification.

For example:

    %macro foo 1-3
            ; Do something
    %endmacro
    %unmacro foo 1-3

removes the previously defined macro `foo`, but

    %macro bar 1-3
            ; Do something
    %endmacro
    %unmacro bar 1

does not remove the macro `bar`, since the argument specification does not match exactly.

### 4.4 Conditional Assembly

Similarly to the C preprocessor, NASM allows sections of a source file to be assembled only if certain conditions are met. The general syntax of this feature looks like this:

    %if<condition>
        ; some code which only appears if <condition> is met
    %elif<condition2>
        ; only appears if <condition> is not met but <condition2> is
    %else
        ; this appears if neither <condition> nor <condition2> was met
    %endif

The inverse forms `%ifn` and `%elifn` are also supported.

The `%else` clause is optional, as is the `%elif` clause. You can have more than one `%elif` clause as well.

There are a number of variants of the `%if` directive. Each has its corresponding `%elif`, `%ifn`, and `%elifn` directives; for example, the equivalents to the `%ifdef` directive are `%elifdef`, `%ifndef`, and `%elifndef`.

#### 4.4.1 `%ifdef`: Testing Single-Line Macro Existence

Beginning a conditional-assembly block with the line `%ifdef MACRO` will assemble the subsequent code if, and only if, a single-line macro called `MACRO` is defined. If not, then the `%elif` and `%else` blocks (if any) will be processed instead.

For example, when debugging a program, you might want to write code such as

              ; perform some function
    %ifdef DEBUG
              writefile 2,"Function performed successfully",13,10
    %endif
              ; go and do something else

Then you could use the command-line option `-dDEBUG` to create a version of the program which produced debugging messages, and remove the option to generate the final release version of the program.

You can test for a macro not being defined by using `%ifndef` instead of `%ifdef`. You can also test for macro definitions in `%elif` blocks by using `%elifdef` and `%elifndef`.

#### 4.4.2 `%ifmacro`: Testing Multi-Line Macro Existence

The `%ifmacro` directive operates in the same way as the `%ifdef` directive, except that it checks for the existence of a multi-line macro.

For example, you may be working with a large project and not have control over the macros in a library. You may want to create a macro with one name if it doesn't already exist, and another name if one with that name does exist.

The `%ifmacro` is considered true if defining a macro with the given name and number of arguments would cause a definitions conflict. For example:

    %ifmacro MyMacro 1-3

         %error "MyMacro 1-3" causes a conflict with an existing macro.

    %else

         %macro MyMacro 1-3

                 ; insert code to define the macro

         %endmacro

    %endif

This will create the macro "MyMacro 1-3" if no macro already exists which would conflict with it, and emits a warning if there would be a definition conflict.

You can test for the macro not existing by using the `%ifnmacro` instead of `%ifmacro`. Additional tests can be performed in `%elif` blocks by using `%elifmacro` and `%elifnmacro`.

#### 4.4.3 `%ifctx`: Testing the Context Stack

The conditional-assembly construct `%ifctx` will cause the subsequent code to be assembled if and only if the top context on the preprocessor's context stack has the same name as one of the arguments. As with `%ifdef`, the inverse and `%elif` forms `%ifnctx`, `%elifctx` and `%elifnctx` are also supported.

For more details of the context stack, see section 4.7. For a sample use of `%ifctx`, see section 4.7.5.

#### 4.4.4 `%if`: Testing Arbitrary Numeric Expressions

The conditional-assembly construct `%if expr` will cause the subsequent code to be assembled if and only if the value of the numeric expression `expr` is non-zero. An example of the use of this feature is in deciding when to break out of a `%rep` preprocessor loop: see section 4.5 for a detailed example.

The expression given to `%if`, and its counterpart `%elif`, is a critical expression (see section 3.8).

`%if` extends the normal NASM expression syntax, by providing a set of relational operators which are not normally available in expressions. The operators `=`, `<`, `>`, `<=`, `>=` and `<>` test equality, less-than, greater-than, less-or-equal, greater-or-equal and not-equal respectively. The C-like forms `==` and `!=` are supported as alternative forms of `=` and `<>`. In addition, low-priority logical operators `&&`, `^^` and `||` are provided, supplying logical AND, logical XOR and logical OR. These work like the C logical operators (although C has no logical XOR), in that they always return either 0 or 1, and treat any non-zero input as 1 (so that `^^`, for example, returns 1 if exactly one of its inputs is zero, and 0 otherwise). The relational operators also return 1 for true and 0 for false.

Like other `%if` constructs, `%if` has a counterpart `%elif`, and negative forms `%ifn` and `%elifn`.

#### 4.4.5 `%ifidn` and `%ifidni`: Testing Exact Text Identity

The construct `%ifidn text1,text2` will cause the subsequent code to be assembled if and only if `text1` and `text2`, after expanding single-line macros, are identical pieces of text. Differences in white space are not counted.

`%ifidni` is similar to `%ifidn`, but is case-insensitive.

For example, the following macro pushes a register or number on the stack, and allows you to treat `IP` as a real register:

    %macro  pushparam 1

      %ifidni %1,ip
            call    %%label
      %%label:
      %else
            push    %1
      %endif

    %endmacro

Like other `%if` constructs, `%ifidn` has a counterpart `%elifidn`, and negative forms `%ifnidn` and `%elifnidn`. Similarly, `%ifidni` has counterparts `%elifidni`, `%ifnidni` and `%elifnidni`.

#### 4.4.6 `%ifid`, `%ifnum`, `%ifstr`: Testing Token Types

Some macros will want to perform different tasks depending on whether they are passed a number, a string, or an identifier. For example, a string output macro might want to be able to cope with being passed either a string constant or a pointer to an existing string.

The conditional assembly construct `%ifid`, taking one parameter (which may be blank), assembles the subsequent code if and only if the first token in the parameter exists and is an identifier. `%ifnum` works similarly, but tests for the token being a numeric constant; `%ifstr` tests for it being a string.

For example, the `writefile` macro defined in section 4.3.3 can be extended to take advantage of `%ifstr` in the following fashion:

    %macro writefile 2-3+

      %ifstr %2
            jmp     %%endstr
        %if %0 = 3
          %%str:    db      %2,%3
        %else
          %%str:    db      %2
        %endif
          %%endstr: mov     dx,%%str
                    mov     cx,%%endstr-%%str
      %else
                    mov     dx,%2
                    mov     cx,%3
      %endif
                    mov     bx,%1
                    mov     ah,0x40
                    int     0x21

    %endmacro

Then the `writefile` macro can cope with being called in either of the following two ways:

            writefile [file], strpointer, length
            writefile [file], "hello", 13, 10

In the first, `strpointer` is used as the address of an already-declared string, and `length` is used as its length; in the second, a string is given to the macro, which therefore declares it itself and works out the address and length for itself.

Note the use of `%if` inside the `%ifstr`: this is to detect whether the macro was passed two arguments (so the string would be a single string constant, and `db %2` would be adequate) or more (in which case, all but the first two would be lumped together into `%3`, and `db %2,%3` would be required).

The usual `%elif`..., `%ifn`..., and `%elifn`... versions exist for each of `%ifid`, `%ifnum` and `%ifstr`.

#### 4.4.7 `%iftoken`: Test for a Single Token

Some macros will want to do different things depending on if it is passed a single token (e.g. paste it to something else using `%+`) versus a multi-token sequence.

The conditional assembly construct `%iftoken` assembles the subsequent code if and only if the expanded parameters consist of exactly one token, possibly surrounded by whitespace.

For example:

    %iftoken 1

will assemble the subsequent code, but

    %iftoken -1

will not, since `-1` contains two tokens: the unary minus operator `-`, and the number `1`.

The usual `%eliftoken`, `%ifntoken`, and `%elifntoken` variants are also provided.

#### 4.4.8 `%ifempty`: Test for Empty Expansion

The conditional assembly construct `%ifempty` assembles the subsequent code if and only if the expanded parameters do not contain any tokens at all, whitespace excepted.

The usual `%elifempty`, `%ifnempty`, and `%elifnempty` variants are also provided.

### 4.5 Preprocessor Loops: `%rep`

NASM's `TIMES` prefix, though useful, cannot be used to invoke a multi-line macro multiple times, because it is processed by NASM after macros have already been expanded. Therefore NASM provides another form of loop, this time at the preprocessor level: `%rep`.

The directives `%rep` and `%endrep` (`%rep` takes a numeric argument, which can be an expression; `%endrep` takes no arguments) can be used to enclose a chunk of code, which is then replicated as many times as specified by the preprocessor:

    %assign i 0
    %rep    64
            inc     word [table+2*i]
    %assign i i+1
    %endrep

This will generate a sequence of 64 `INC` instructions, incrementing every word of memory from `[table]` to `[table+126]`.

For more complex termination conditions, or to break out of a repeat loop part way along, you can use the `%exitrep` directive to terminate the loop, like this:

    fibonacci:
    %assign i 0
    %assign j 1
    %rep 100
    %if j > 65535
        %exitrep
    %endif
            dw j
    %assign k j+i
    %assign i j
    %assign j k
    %endrep

    fib_number equ ($-fibonacci)/2

This produces a list of all the Fibonacci numbers that will fit in 16 bits. Note that a maximum repeat count must still be given to `%rep`. This is to prevent the possibility of NASM getting into an infinite loop in the preprocessor, which (on multitasking or multi-user systems) would typically cause all the system memory to be gradually used up and other applications to start crashing.

### 4.6 Source Files and Dependencies

These commands allow you to split your sources into multiple files.

#### 4.6.1 `%include`: Including Other Files

Using, once again, a very similar syntax to the C preprocessor, NASM's preprocessor lets you include other source files into your code. This is done by the use of the `%include` directive:

    %include "macros.mac"

will include the contents of the file `macros.mac` into the source file containing the `%include` directive.

Include files are searched for in the current directory (the directory you're in when you run NASM, as opposed to the location of the NASM executable or the location of the source file), plus any directories specified on the NASM command line using the `-i` option.

The standard C idiom for preventing a file being included more than once is just as applicable in NASM: if the file `macros.mac` has the form

    %ifndef MACROS_MAC
        %define MACROS_MAC
        ; now define some macros
    %endif

then including the file more than once will not cause errors, because the second time the file is included nothing will happen because the macro `MACROS_MAC` will already be defined.

You can force a file to be included even if there is no `%include` directive that explicitly includes it, by using the `-p` option on the NASM command line (see section 2.1.17).

#### 4.6.2 `%pathsearch`: Search the Include Path

The `%pathsearch` directive takes a single-line macro name and a filename, and declare or redefines the specified single-line macro to be the include-path-resolved version of the filename, if the file exists (otherwise, it is passed unchanged.)

For example,

    %pathsearch MyFoo "foo.bin"

... with `-Ibins/` in the include path may end up defining the macro `MyFoo` to be `"bins/foo.bin"`.

#### 4.6.3 `%depend`: Add Dependent Files

The `%depend` directive takes a filename and adds it to the list of files to be emitted as dependency generation when the `-M` options and its relatives (see section 2.1.4) are used. It produces no output.

This is generally used in conjunction with `%pathsearch`. For example, a simplified version of the standard macro wrapper for the `INCBIN` directive looks like:

    %imacro incbin 1-2+ 0
    %pathsearch dep %1
    %depend dep
            incbin dep,%2
    %endmacro

This first resolves the location of the file into the macro `dep`, then adds it to the dependency lists, and finally issues the assembler-level `INCBIN` directive.

#### 4.6.4 `%use`: Include Standard Macro Package

The `%use` directive is similar to `%include`, but rather than including the contents of a file, it includes a named standard macro package. The standard macro packages are part of NASM, and are described in chapter 5.

Unlike the `%include` directive, package names for the `%use` directive do not require quotes, but quotes are permitted. In NASM 2.04 and 2.05 the unquoted form would be macro-expanded; this is no longer true. Thus, the following lines are equivalent:

    %use altreg
    %use 'altreg'

Standard macro packages are protected from multiple inclusion. When a standard macro package is used, a testable single-line macro of the form `__USE_`package`__` is also defined, see section 4.11.8.

### 4.7 The Context Stack

Having labels that are local to a macro definition is sometimes not quite powerful enough: sometimes you want to be able to share labels between several macro calls. An example might be a `REPEAT` ... `UNTIL` loop, in which the expansion of the `REPEAT` macro would need to be able to refer to a label which the `UNTIL` macro had defined. However, for such a macro you would also want to be able to nest these loops.

NASM provides this level of power by means of a context stack. The preprocessor maintains a stack of contexts, each of which is characterized by a name. You add a new context to the stack using the `%push` directive, and remove one using `%pop`. You can define labels that are local to a particular context on the stack.

#### 4.7.1 `%push` and `%pop`: Creating and Removing Contexts

The `%push` directive is used to create a new context and place it on the top of the context stack. `%push` takes an optional argument, which is the name of the context. For example:

    %push    foobar

This pushes a new context called `foobar` on the stack. You can have several contexts on the stack with the same name: they can still be distinguished. If no name is given, the context is unnamed (this is normally used when both the `%push` and the `%pop` are inside a single macro definition.)

The directive `%pop`, taking one optional argument, removes the top context from the context stack and destroys it, along with any labels associated with it. If an argument is given, it must match the name of the current context, otherwise it will issue an error.

#### 4.7.2 Context-Local Labels

Just as the usage `%%foo` defines a label which is local to the particular macro call in which it is used, the usage `%$foo` is used to define a label which is local to the context on the top of the context stack. So the `REPEAT` and `UNTIL` example given above could be implemented by means of:

    %macro repeat 0

        %push   repeat
        %$begin:

    %endmacro

    %macro until 1

            j%-1    %$begin
        %pop

    %endmacro

and invoked by means of, for example,

            mov     cx,string
            repeat
            add     cx,3
            scasb
            until   e

which would scan every fourth byte of a string in search of the byte in `AL`.

If you need to define, or access, labels local to the context below the top one on the stack, you can use `%$$foo`, or `%$$$foo` for the context below that, and so on.

#### 4.7.3 Context-Local Single-Line Macros

NASM also allows you to define single-line macros which are local to a particular context, in just the same way:

    %define %$localmac 3

will define the single-line macro `%$localmac` to be local to the top context on the stack. Of course, after a subsequent `%push`, it can then still be accessed by the name `%$$localmac`.

#### 4.7.4 `%repl`: Renaming a Context

If you need to change the name of the top context on the stack (in order, for example, to have it respond differently to `%ifctx`), you can execute a `%pop` followed by a `%push`; but this will have the side effect of destroying all context-local labels and macros associated with the context that was just popped.

NASM provides the directive `%repl`, which replaces a context with a different name, without touching the associated macros and labels. So you could replace the destructive code

    %pop
    %push   newname

with the non-destructive version `%repl newname`.

#### 4.7.5 Example Use of the Context Stack: Block IFs

This example makes use of almost all the context-stack features, including the conditional-assembly construct `%ifctx`, to implement a block IF statement as a set of macros.

    %macro if 1

        %push if
        j%-1  %$ifnot

    %endmacro

    %macro else 0

      %ifctx if
            %repl   else
            jmp     %$ifend
            %$ifnot:
      %else
            %error  "expected `if' before `else'"
      %endif

    %endmacro

    %macro endif 0

      %ifctx if
            %$ifnot:
            %pop
      %elifctx      else
            %$ifend:
            %pop
      %else
            %error  "expected `if' or `else' before `endif'"
      %endif

    %endmacro

This code is more robust than the `REPEAT` and `UNTIL` macros given in section 4.7.2, because it uses conditional assembly to check that the macros are issued in the right order (for example, not calling `endif` before `if`) and issues a `%error` if they're not.

In addition, the `endif` macro has to be able to cope with the two distinct cases of either directly following an `if`, or following an `else`. It achieves this, again, by using conditional assembly to do different things depending on whether the context on top of the stack is `if` or `else`.

The `else` macro has to preserve the context on the stack, in order to have the `%$ifnot` referred to by the `if` macro be the same as the one defined by the `endif` macro, but has to change the context's name so that `endif` will know there was an intervening `else`. It does this by the use of `%repl`.

A sample usage of these macros might look like:

            cmp     ax,bx

            if ae
                   cmp     bx,cx

                   if ae
                           mov     ax,cx
                   else
                           mov     ax,bx
                   endif

            else
                   cmp     ax,cx

                   if ae
                           mov     ax,cx
                   endif

            endif

The block-`IF` macros handle nesting quite happily, by means of pushing another context, describing the inner `if`, on top of the one describing the outer `if`; thus `else` and `endif` always refer to the last unmatched `if` or `else`.

### 4.8 Stack Relative Preprocessor Directives

The following preprocessor directives provide a way to use labels to refer to local variables allocated on the stack.

- `%arg` (see section 4.8.1)
- `%stacksize` (see section 4.8.2)
- `%local` (see section 4.8.3)

#### 4.8.1 `%arg` Directive

The `%arg` directive is used to simplify the handling of parameters passed on the stack. Stack based parameter passing is used by many high level languages, including C, C++ and Pascal.

While NASM has macros which attempt to duplicate this functionality (see section 8.4.5), the syntax is not particularly convenient to use and is not TASM compatible. Here is an example which shows the use of `%arg` without any external macros:

    some_function:

        %push     mycontext        ; save the current context
        %stacksize large           ; tell NASM to use bp
        %arg      i:word, j_ptr:word

            mov     ax,[i]
            mov     bx,[j_ptr]
            add     ax,[bx]
            ret

        %pop                       ; restore original context

This is similar to the procedure defined in section 8.4.5 and adds the value in i to the value pointed to by j_ptr and returns the sum in the ax register. See section 4.7.1 for an explanation of `push` and `pop` and the use of context stacks.

#### 4.8.2 `%stacksize` Directive

The `%stacksize` directive is used in conjunction with the `%arg` (see section 4.8.1) and the `%local` (see section 4.8.3) directives. It tells NASM the default size to use for subsequent `%arg` and `%local` directives. The `%stacksize` directive takes one required argument which is one of `flat`, `flat64`, `large` or `small`.

    %stacksize flat

This form causes NASM to use stack-based parameter addressing relative to `ebp` and it assumes that a near form of call was used to get to this label (i.e. that `eip` is on the stack).

    %stacksize flat64

This form causes NASM to use stack-based parameter addressing relative to `rbp` and it assumes that a near form of call was used to get to this label (i.e. that `rip` is on the stack).

    %stacksize large

This form uses `bp` to do stack-based parameter addressing and assumes that a far form of call was used to get to this address (i.e. that `ip` and `cs` are on the stack).

    %stacksize small

This form also uses `bp` to address stack parameters, but it is different from `large` because it also assumes that the old value of bp is pushed onto the stack (i.e. it expects an `ENTER` instruction). In other words, it expects that `bp`, `ip` and `cs` are on the top of the stack, underneath any local space which may have been allocated by `ENTER`. This form is probably most useful when used in combination with the `%local` directive (see section 4.8.3).

#### 4.8.3 `%local` Directive

The `%local` directive is used to simplify the use of local temporary stack variables allocated in a stack frame. Automatic local variables in C are an example of this kind of variable. The `%local` directive is most useful when used with the `%stacksize` (see section 4.8.2 and is also compatible with the `%arg` directive (see section 4.8.1). It allows simplified reference to variables on the stack which have been allocated typically by using the `ENTER` instruction. An example of its use is the following:

    silly_swap:

        %push mycontext             ; save the current context
        %stacksize small            ; tell NASM to use bp
        %assign %$localsize 0       ; see text for explanation
        %local old_ax:word, old_dx:word

            enter   %$localsize,0   ; see text for explanation
            mov     [old_ax],ax     ; swap ax & bx
            mov     [old_dx],dx     ; and swap dx & cx
            mov     ax,bx
            mov     dx,cx
            mov     bx,[old_ax]
            mov     cx,[old_dx]
            leave                   ; restore old bp
            ret                     ;

        %pop                        ; restore original context

The `%$localsize` variable is used internally by the `%local` directive and must be defined within the current context before the `%local` directive may be used. Failure to do so will result in one expression syntax error for each `%local` variable declared. It then may be used in the construction of an appropriately sized ENTER instruction as shown in the example.

### 4.9 Reporting User-Defined Errors: `%error`, `%warning`, `%fatal`

The preprocessor directive `%error` will cause NASM to report an error if it occurs in assembled code. So if other users are going to try to assemble your source files, you can ensure that they define the right macros by means of code like this:

    %ifdef F1
        ; do some setup
    %elifdef F2
        ; do some different setup
    %else
        %error "Neither F1 nor F2 was defined."
    %endif

Then any user who fails to understand the way your code is supposed to be assembled will be quickly warned of their mistake, rather than having to wait until the program crashes on being run and then not knowing what went wrong.

Similarly, `%warning` issues a warning, but allows assembly to continue:

    %ifdef F1
        ; do some setup
    %elifdef F2
        ; do some different setup
    %else
        %warning "Neither F1 nor F2 was defined, assuming F1."
        %define F1
    %endif

`%error` and `%warning` are issued only on the final assembly pass. This makes them safe to use in conjunction with tests that depend on symbol values.

`%fatal` terminates assembly immediately, regardless of pass. This is useful when there is no point in continuing the assembly further, and doing so is likely just going to cause a spew of confusing error messages.

It is optional for the message string after `%error`, `%warning` or `%fatal` to be quoted. If it is not, then single-line macros are expanded in it, which can be used to display more information to the user. For example:

    %if foo > 64
        %assign foo_over foo-64
        %error foo is foo_over bytes too large
    %endif

### 4.10 Other Preprocessor Directives

NASM also has preprocessor directives which allow access to information from external sources. Currently they include:

- `%line` enables NASM to correctly handle the output of another preprocessor (see section 4.10.1).
- `%!` enables NASM to read in the value of an environment variable, which can then be used in your program (see section 4.10.2).

#### 4.10.1 `%line` Directive

The `%line` directive is used to notify NASM that the input line corresponds to a specific line number in another file. Typically this other file would be an original source file, with the current NASM input being the output of a pre-processor. The `%line` directive allows NASM to output messages which indicate the line number of the original source file, instead of the file that is being read by NASM.

This preprocessor directive is not generally of use to programmers, by may be of interest to preprocessor authors. The usage of the `%line` preprocessor directive is as follows:

    %line nnn[+mmm] [filename]

In this directive, `nnn` identifies the line of the original source file which this line corresponds to. `mmm` is an optional parameter which specifies a line increment value; each line of the input file read in is considered to correspond to `mmm` lines of the original source file. Finally, `filename` is an optional parameter which specifies the file name of the original source file.

After reading a `%line` preprocessor directive, NASM will report all file name and line numbers relative to the values specified therein.

#### 4.10.2 `%!``<env>`: Read an environment variable.

The `%!<env>` directive makes it possible to read the value of an environment variable at assembly time. This could, for example, be used to store the contents of an environment variable into a string, which could be used at some other point in your code.

For example, suppose that you have an environment variable `FOO`, and you want the contents of `FOO` to be embedded in your program. You could do that as follows:

    %defstr FOO    %!FOO

See section 4.1.8 for notes on the `%defstr` directive.

### 4.11 Standard Macros

NASM defines a set of standard macros, which are already defined when it starts to process any source file. If you really need a program to be assembled with no pre-defined macros, you can use the `%clear` directive to empty the preprocessor of everything but context-local preprocessor variables and single-line macros.

Most user-level assembler directives (see chapter 6) are implemented as macros which invoke primitive directives; these are described in chapter 6. The rest of the standard macro set is described here.

#### 4.11.1 NASM Version Macros

The single-line macros `__NASM_MAJOR__`, `__NASM_MINOR__`, `__NASM_SUBMINOR__` and `___NASM_PATCHLEVEL__` expand to the major, minor, subminor and patch level parts of the version number of NASM being used. So, under NASM 0.98.32p1 for example, `__NASM_MAJOR__` would be defined to be 0, `__NASM_MINOR__` would be defined as 98, `__NASM_SUBMINOR__` would be defined to 32, and `___NASM_PATCHLEVEL__` would be defined as 1.

Additionally, the macro `__NASM_SNAPSHOT__` is defined for automatically generated snapshot releases only.

#### 4.11.2 `__NASM_VERSION_ID__`: NASM Version ID

The single-line macro `__NASM_VERSION_ID__` expands to a dword integer representing the full version number of the version of nasm being used. The value is the equivalent to `__NASM_MAJOR__`, `__NASM_MINOR__`, `__NASM_SUBMINOR__` and `___NASM_PATCHLEVEL__` concatenated to produce a single doubleword. Hence, for 0.98.32p1, the returned number would be equivalent to:

            dd      0x00622001

or

            db      1,32,98,0

Note that the above lines are generate exactly the same code, the second line is used just to give an indication of the order that the separate values will be present in memory.

#### 4.11.3 `__NASM_VER__`: NASM Version string

The single-line macro `__NASM_VER__` expands to a string which defines the version number of nasm being used. So, under NASM 0.98.32 for example,

            db      __NASM_VER__

would expand to

            db      "0.98.32"

#### 4.11.4 `__FILE__` and `__LINE__`: File Name and Line Number

Like the C preprocessor, NASM allows the user to find out the file name and line number containing the current instruction. The macro `__FILE__` expands to a string constant giving the name of the current input file (which may change through the course of assembly if `%include` directives are used), and `__LINE__` expands to a numeric constant giving the current line number in the input file.

These macros could be used, for example, to communicate debugging information to a macro, since invoking `__LINE__` inside a macro definition (either single-line or multi-line) will return the line number of the macro call, rather than definition. So to determine where in a piece of code a crash is occurring, for example, one could write a routine `stillhere`, which is passed a line number in `EAX` and outputs something like `line 155: still here'. You could then write a macro

    %macro  notdeadyet 0

            push    eax
            mov     eax,__LINE__
            call    stillhere
            pop     eax

    %endmacro

and then pepper your code with calls to `notdeadyet` until you find the crash point.

#### 4.11.5 `__BITS__`: Current BITS Mode

The `__BITS__` standard macro is updated every time that the BITS mode is set using the `BITS XX` or `[BITS XX]` directive, where XX is a valid mode number of 16, 32 or 64. `__BITS__` receives the specified mode number and makes it globally available. This can be very useful for those who utilize mode-dependent macros.

#### 4.11.6 `__OUTPUT_FORMAT__`: Current Output Format

The `__OUTPUT_FORMAT__` standard macro holds the current Output Format, as given by the `-f` option or NASM's default. Type `nasm -hf` for a list.

    %ifidn __OUTPUT_FORMAT__, win32
     %define NEWLINE 13, 10
    %elifidn __OUTPUT_FORMAT__, elf32
     %define NEWLINE 10
    %endif

#### 4.11.7 Assembly Date and Time Macros

NASM provides a variety of macros that represent the timestamp of the assembly session.

- The `__DATE__` and `__TIME__` macros give the assembly date and time as strings, in ISO 8601 format (`"YYYY-MM-DD"` and `"HH:MM:SS"`, respectively.)
- The `__DATE_NUM__` and `__TIME_NUM__` macros give the assembly date and time in numeric form; in the format `YYYYMMDD` and `HHMMSS` respectively.
- The `__UTC_DATE__` and `__UTC_TIME__` macros give the assembly date and time in universal time (UTC) as strings, in ISO 8601 format (`"YYYY-MM-DD"` and `"HH:MM:SS"`, respectively.) If the host platform doesn't provide UTC time, these macros are undefined.
- The `__UTC_DATE_NUM__` and `__UTC_TIME_NUM__` macros give the assembly date and time universal time (UTC) in numeric form; in the format `YYYYMMDD` and `HHMMSS` respectively. If the host platform doesn't provide UTC time, these macros are undefined.
- The `__POSIX_TIME__` macro is defined as a number containing the number of seconds since the POSIX epoch, 1 January 1970 00:00:00 UTC; excluding any leap seconds. This is computed using UTC time if available on the host platform, otherwise it is computed using the local time as if it was UTC.

All instances of time and date macros in the same assembly session produce consistent output. For example, in an assembly session started at 42 seconds after midnight on January 1, 2010 in Moscow (timezone UTC+3) these macros would have the following values, assuming, of course, a properly configured environment with a correct clock:

          __DATE__             "2010-01-01"
          __TIME__             "00:00:42"
          __DATE_NUM__         20100101
          __TIME_NUM__         000042
          __UTC_DATE__         "2009-12-31"
          __UTC_TIME__         "21:00:42"
          __UTC_DATE_NUM__     20091231
          __UTC_TIME_NUM__     210042
          __POSIX_TIME__       1262293242

#### 4.11.8 `__USE_`package`__`: Package Include Test

When a standard macro package (see chapter 5) is included with the `%use` directive (see section 4.6.4), a single-line macro of the form `__USE_`package`__` is automatically defined. This allows testing if a particular package is invoked or not.

For example, if the `altreg` package is included (see section 5.1), then the macro `__USE_ALTREG__` is defined.

#### 4.11.9 `__PASS__`: Assembly Pass

The macro `__PASS__` is defined to be `1` on preparatory passes, and `2` on the final pass. In preprocess-only mode, it is set to `3`, and when running only to generate dependencies (due to the `-M` or `-MG` option, see section 2.1.4) it is set to `0`.

Avoid using this macro if at all possible. It is tremendously easy to generate very strange errors by misusing it, and the semantics may change in future versions of NASM.

#### 4.11.10 `STRUC` and `ENDSTRUC`: Declaring Structure Data Types

The core of NASM contains no intrinsic means of defining data structures; instead, the preprocessor is sufficiently powerful that data structures can be implemented as a set of macros. The macros `STRUC` and `ENDSTRUC` are used to define a structure data type.

`STRUC` takes one or two parameters. The first parameter is the name of the data type. The second, optional parameter is the base offset of the structure. The name of the data type is defined as a symbol with the value of the base offset, and the name of the data type with the suffix `_size` appended to it is defined as an `EQU` giving the size of the structure. Once `STRUC` has been issued, you are defining the structure, and should define fields using the `RESB` family of pseudo-instructions, and then invoke `ENDSTRUC` to finish the definition.

For example, to define a structure called `mytype` containing a longword, a word, a byte and a string of bytes, you might code

    struc   mytype

      mt_long:      resd    1
      mt_word:      resw    1
      mt_byte:      resb    1
      mt_str:       resb    32

    endstruc

The above code defines six symbols: `mt_long` as 0 (the offset from the beginning of a `mytype` structure to the longword field), `mt_word` as 4, `mt_byte` as 6, `mt_str` as 7, `mytype_size` as 39, and `mytype` itself as zero.

The reason why the structure type name is defined at zero by default is a side effect of allowing structures to work with the local label mechanism: if your structure members tend to have the same names in more than one structure, you can define the above structure like this:

    struc mytype

      .long:        resd    1
      .word:        resw    1
      .byte:        resb    1
      .str:         resb    32

    endstruc

This defines the offsets to the structure fields as `mytype.long`, `mytype.word`, `mytype.byte` and `mytype.str`.

NASM, since it has no intrinsic structure support, does not support any form of period notation to refer to the elements of a structure once you have one (except the above local-label notation), so code such as `mov ax,[mystruc.mt_word]` is not valid. `mt_word` is a constant just like any other constant, so the correct syntax is `mov ax,[mystruc+mt_word]` or `mov ax,[mystruc+mytype.word]`.

Sometimes you only have the address of the structure displaced by an offset. For example, consider this standard stack frame setup:

    push ebp
    mov ebp, esp
    sub esp, 40

In this case, you could access an element by subtracting the offset:

    mov [ebp - 40 + mytype.word], ax

However, if you do not want to repeat this offset, you can use -40 as a base offset:

    struc mytype, -40

And access an element this way:

    mov [ebp + mytype.word], ax

#### 4.11.11 `ISTRUC`, `AT` and `IEND`: Declaring Instances of Structures

Having defined a structure type, the next thing you typically want to do is to declare instances of that structure in your data segment. NASM provides an easy way to do this in the `ISTRUC` mechanism. To declare a structure of type `mytype` in a program, you code something like this:

    mystruc:
        istruc mytype

            at mt_long, dd      123456
            at mt_word, dw      1024
            at mt_byte, db      'x'
            at mt_str,  db      'hello, world', 13, 10, 0

        iend

The function of the `AT` macro is to make use of the `TIMES` prefix to advance the assembly position to the correct point for the specified structure field, and then to declare the specified data. Therefore the structure fields must be declared in the same order as they were specified in the structure definition.

If the data to go in a structure field requires more than one source line to specify, the remaining source lines can easily come after the `AT` line. For example:

            at mt_str,  db      123,134,145,156,167,178,189
                        db      190,100,0

Depending on personal taste, you can also omit the code part of the `AT` line completely, and start the structure field on the next line:

            at mt_str
                    db      'hello, world'
                    db      13,10,0

#### 4.11.12 `ALIGN` and `ALIGNB`: Data Alignment

The `ALIGN` and `ALIGNB` macros provides a convenient way to align code or data on a word, longword, paragraph or other boundary. (Some assemblers call this directive `EVEN`.) The syntax of the `ALIGN` and `ALIGNB` macros is

            align   4               ; align on 4-byte boundary
            align   16              ; align on 16-byte boundary
            align   8,db 0          ; pad with 0s rather than NOPs
            align   4,resb 1        ; align to 4 in the BSS
            alignb  4               ; equivalent to previous line

Both macros require their first argument to be a power of two; they both compute the number of additional bytes required to bring the length of the current section up to a multiple of that power of two, and then apply the `TIMES` prefix to their second argument to perform the alignment.

If the second argument is not specified, the default for `ALIGN` is `NOP`, and the default for `ALIGNB` is `RESB 1`. So if the second argument is specified, the two macros are equivalent. Normally, you can just use `ALIGN` in code and data sections and `ALIGNB` in BSS sections, and never need the second argument except for special purposes.

`ALIGN` and `ALIGNB`, being simple macros, perform no error checking: they cannot warn you if their first argument fails to be a power of two, or if their second argument generates more than one byte of code. In each of these cases they will silently do the wrong thing.

`ALIGNB` (or `ALIGN` with a second argument of `RESB 1`) can be used within structure definitions:

    struc mytype2

      mt_byte:
            resb 1
            alignb 2
      mt_word:
            resw 1
            alignb 4
      mt_long:
            resd 1
      mt_str:
            resb 32

    endstruc

This will ensure that the structure members are sensibly aligned relative to the base of the structure.

A final caveat: `ALIGN` and `ALIGNB` work relative to the beginning of the section, not the beginning of the address space in the final executable. Aligning to a 16-byte boundary when the section you're in is only guaranteed to be aligned to a 4-byte boundary, for example, is a waste of effort. Again, NASM does not check that the section's alignment characteristics are sensible for the use of `ALIGN` or `ALIGNB`.

See also the `smartalign` standard macro package, section 5.2.

Next Chapter | Previous Chapter | Contents | Index