Mojo::IOLoop(3p)      User Contributed Perl Documentation     Mojo::IOLoop(3p)



NAME
       Mojo::IOLoop - Minimalistic Reactor For Async TCP Clients And Servers

SYNOPSIS
         use Mojo::IOLoop;

         # Create loop
         my $loop = Mojo::IOLoop->new;

         # Listen on port 3000
         $loop->listen(
           port => 3000,
           on_read => sub {
             my ($self, $id, $chunk) = @_;

             # Process input
             print $chunk;

             # Got some data, time to write
             $self->write($id, 'HTTP/1.1 200 OK');
           }
         );

         # Connect to port 3000 with TLS activated
         my $id = $loop->connect(
           address => 'localhost',
           port => 3000,
           tls => 1,
           on_connect => sub {
             my ($self, $id) = @_;

             # Write request
             $self->write($id, "GET / HTTP/1.1\r\n\r\n");
           },
           on_read => sub {
             my ($self, $id, $chunk) = @_;

             # Process input
             print $chunk;
           }
         );

         # Add a timer
         $loop->timer(5 => sub {
           my $self = shift;
           $self->drop($id);
         });

         # Start and stop loop
         $loop->start;
         $loop->stop;

DESCRIPTION
       Mojo::IOLoop is a very minimalistic reactor that has been reduced to
       the absolute minimal feature set required to build solid and scalable
       async TCP clients and servers.

       Optional modules IO::KQueue, IO::Epoll, IO::Socket::IP and
       IO::Socket::SSL are supported transparently and used if installed.

       A TLS certificate and key are also built right in to make writing test
       servers as easy as possible.

ATTRIBUTES
       Mojo::IOLoop implements the following attributes.

   "accept_timeout"
         my $timeout = $loop->accept_timeout;
         $loop       = $loop->accept_timeout(5);

       Maximum time in seconds a connection can take to be accepted before
       being dropped, defaults to 3.

   "connect_timeout"
         my $timeout = $loop->connect_timeout;
         $loop       = $loop->connect_timeout(5);

       Maximum time in seconds a conenction can take to be connected before
       being dropped, defaults to 3.

   "dns_timeout"
         my $timeout = $loop->dns_timeout;
         $loop       = $loop->dns_timeout(5);

       Maximum time in seconds a "DNS" lookup can take, defaults to 3.  Note
       that this attribute is EXPERIMENTAL and might change without warning!

   "max_accepts"
         my $max = $loop->max_accepts;
         $loop   = $loop->max_accepts(1000);

       The maximum number of connections this loop is allowed to accept before
       shutting down gracefully without interrupting existing connections,
       defaults to 0.  Setting the value to 0 will allow this loop to accept
       new connections infinitely.  Note that this attribute is EXPERIMENTAL
       and might change without warning!

   "max_connections"
         my $max = $loop->max_connections;
         $loop   = $loop->max_connections(1000);

       The maximum number of parallel connections this loop is allowed to
       handle before stopping to accept new incoming connections, defaults to
       1000.  Setting the value to 0 will make this loop stop accepting new
       connections and allow it to shutdown gracefully without interrupting
       existing connections.

   "on_lock"
         my $cb = $loop->on_lock;
         $loop  = $loop->on_lock(sub {...});

       A locking callback that decides if this loop is allowed to accept new
       incoming connections, used to sync multiple server processes.  The
       callback should return true or false.  Note that exceptions in this
       callback are not captured.

         $loop->on_lock(sub {
           my ($loop, $blocking) = @_;

           # Got the lock, listen for new connections
           return 1;
         });

   "on_unlock"
         my $cb = $loop->on_unlock;
         $loop  = $loop->on_unlock(sub {...});

       A callback to free the accept lock, used to sync multiple server
       processes.  Note that exceptions in this callback are not captured.

   "timeout"
         my $timeout = $loop->timeout;
         $loop       = $loop->timeout(5);

       Maximum time in seconds our loop waits for new events to happen,
       defaults to 0.025.  Note that a value of 0 would make the loop non-
       blocking.

METHODS
       Mojo::IOLoop inherits all methods from Mojo::Base and implements the
       following new ones.

   "new"
         my $loop = Mojo::IOLoop->new;

       Construct a new Mojo::IOLoop object.  Multiple of these will block each
       other, so use "singleton" instead if possible.

   "connect"
         my $id = Mojo::IOLoop->connect(
           address => '127.0.0.1',
           port    => 3000
         );
         my $id = $loop->connect(
           address => '127.0.0.1',
           port    => 3000
         );

       Open a TCP connection to a remote host.  Note that TLS support depends
       on IO::Socket::SSL and IPv6 support on IO::Socket::IP.

       These options are currently available.

       "address"
         Address or host name of the peer to connect to.

       "handle"
         Use an already prepared handle.

       "on_connect"
         Callback to be invoked once the connection is established.

       "on_error"
         Callback to be invoked if an error event happens on the connection.

       "on_hup"
         Callback to be invoked if the connection gets closed.

       "on_read"
         Callback to be invoked if new data arrives on the connection.

       "port"
         Port to connect to.

       "proto"
         Protocol to use, defaults to "tcp".

       "tls"
         Enable TLS.

       "tls_cert"
         Path to the TLS certificate file.

       "tls_key"
         Path to the TLS key file.

   "connection_timeout"
         my $timeout = $loop->connection_timeout($id);
         $loop       = $loop->connection_timeout($id => 45);

       Maximum amount of time in seconds a connection can be inactive before
       being dropped.

   "dns_servers"
         my @all     = Mojo::IOLoop->dns_servers;
         my @all     = $loop->dns_servers;
         my $current = $loop->dns_servers;
         $loop       = $loop->dns_servers('8.8.8.8', '8.8.4.4');

       IP addresses of "DNS" servers used for non-blocking lookups, defaults
       to the value of "MOJO_DNS_SERVER", auto detection, 8.8.8.8 or 8.8.4.4.
       Note that this method is EXPERIMENTAL and might change without warning!

   "drop"
         $loop = Mojo::IOLoop->drop($id)
         $loop = $loop->drop($id);

       Drop anything with an id.  Connections will be dropped gracefully by
       allowing them to finish writing all data in its write buffer.

   "generate_port"
         my $port = Mojo::IOLoop->generate_port;
         my $port = $loop->generate_port;

       Find a free TCP port, this is a utility function primarily used for
       tests.

   "handle"
         my $handle = $loop->handle($id);

       Get handle for id.  Note that this method is EXPERIMENTAL and might
       change without warning!

   "is_running"
         my $running = Mojo::IOLoop->is_running;
         my $running = $loop->is_running;

       Check if loop is running.

         exit unless Mojo::IOLoop->is_running;

   "listen"
         my $id = Mojo::IOLoop->listen(port => 3000);
         my $id = $loop->listen(port => 3000);
         my $id = $loop->listen({port => 3000});
         my $id = $loop->listen(file => '/foo/myapp.sock');
         my $id = $loop->listen(
           port     => 443,
           tls      => 1,
           tls_cert => '/foo/server.cert',
           tls_key  => '/foo/server.key'
         );

       Create a new listen socket.  Note that TLS support depends on
       IO::Socket::SSL and IPv6 support on IO::Socket::IP.

       These options are currently available.

       "address"
         Local address to listen on, defaults to all.

       "backlog"
         Maximum backlog size, defaults to "SOMAXCONN".

       "file"
         A unix domain socket to listen on.

       "on_accept"
         Callback to invoke for each accepted connection.

       "on_error"
         Callback to be invoked if an error event happens on the connection.

       "on_hup"
         Callback to be invoked if the connection gets closed.

       "on_read"
         Callback to be invoked if new data arrives on the connection.

       "port"
         Port to listen on.

       "tls"
         Enable TLS.

       "tls_cert"
         Path to the TLS cert file, defaulting to a built in test certificate.

       "tls_key"
         Path to the TLS key file, defaulting to a built in test key.

       "tls_ca"
         Path to TLS certificate authority file or directory.

   "local_info"
         my $info = $loop->local_info($id);

       Get local information about a connection.

         my $address = $info->{address};

       These values are to be expected in the returned hash reference.

       "address"
         The local address.

       "port"
         The local port.

   "lookup"
         $loop = Mojo::IOLoop->lookup('mojolicio.us' => sub {...});
         $loop = $loop->lookup('mojolicio.us' => sub {...});

       Lookup "IPv4" or "IPv6" address for domain.  Note that this method is
       EXPERIMENTAL and might change without warning!

         $loop->lookup('mojolicio.us' => sub {
           my ($loop, $address) = @_;
           print "Address: $address\n";
         });

   "on_error"
         $loop = $loop->on_error($id => sub {...});

       Callback to be invoked if an error event happens on the connection.

   "on_hup"
         $loop = $loop->on_hup($id => sub {...});

       Callback to be invoked if the connection gets closed.

   "on_idle"
         my $id = $loop->on_idle(sub {...});

       Callback to be invoked on every reactor tick if no other events
       occurred.  Note that this method is EXPERIMENTAL and might change
       without warning!

   "on_read"
         $loop = $loop->on_read($id => sub {...});

       Callback to be invoked if new data arrives on the connection.

         $loop->on_read($id => sub {
           my ($loop, $id, $chunk) = @_;

           # Process chunk
         });

   "on_tick"
         my $id = $loop->on_tick(sub {...});

       Callback to be invoked on every reactor tick, this for example allows
       you to run multiple reactors next to each other.

         my $loop2 = Mojo::IOLoop->new(timeout => 0);
         Mojo::IOLoop->singleton->on_tick(sub { $loop2->one_tick });

       Note that the loop timeout can be changed dynamically at any time to
       adjust responsiveness.

   "one_tick"
         $loop->one_tick;
         $loop->one_tick('0.25');
         $loop->one_tick(0);

       Run reactor for exactly one tick.

   "remote_info"
         my $info = $loop->remote_info($id);

       Get remote information about a connection.

         my $address = $info->{address};

       These values are to be expected in the returned hash reference.

       "address"
         The remote address.

       "port"
         The remote port.

   "resolve"
         $loop = Mojo::IOLoop->resolve('mojolicio.us', 'A', sub {...});
         $loop = $loop->resolve('mojolicio.us', 'A', sub {...});

       Resolve domain into "A", "AAAA", "CNAME", "MX", "NS", "PTR" or "TXT"
       records, "*" will query for all at once.  Note that this method is
       EXPERIMENTAL and might change without warning!

   "singleton"
         my $loop = Mojo::IOLoop->singleton;

       The global loop object, used to access a single shared loop instance
       from everywhere inside the process.  Many methods also allow you to
       take shortcuts when using the Mojo::IOLoop singleton.

         Mojo::IOLoop->timer(2 => sub { Mojo::IOLoop->stop });
         Mojo::IOLoop->start;

   "start"
         Mojo::IOLoop->start;
         $loop->start;

       Start the loop, this will block until "stop" is called or return
       immediately if the loop is already running.

   "start_tls"
         my $id = $loop->start_tls($id);

       Start new TLS connection inside old connection.  Note that TLS support
       depends on IO::Socket::SSL.

   "stop"
         Mojo::IOLoop->stop;
         $loop->stop;

       Stop the loop immediately, this will not interrupt any existing
       connections and the loop can be restarted by running "start" again.

   "test"
         my $success = $loop->test($id);

       Test for errors and garbage bytes on the connection.  Note that this
       method is EXPERIMENTAL and might change without warning!

   "timer"
         my $id = Mojo::IOLoop->timer(5 => sub {...});
         my $id = $loop->timer(5 => sub {...});
         my $id = $loop->timer(0.25 => sub {...});

       Create a new timer, invoking the callback afer a given amount of
       seconds.

   "write"
         $loop->write($id => 'Hello!');
         $loop->write($id => 'Hello!', sub {...});

       Write data to connection, the optional drain callback will be invoked
       once all data has been written.

SEE ALSO
       Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.



perl v5.12.2                      2011-03-17                  Mojo::IOLoop(3p)
