POE::Component::IRC::Plugin::BotCommand(3p)

NAME
POE::Component::IRC::Plugin::BotCommand - A PoCo-IRC plugin which handles commands issued to your bot

SYNOPSIS
 use POE;
 use POE::Component::Client::DNS;
 use POE::Component::IRC;
 use POE::Component::IRC::Plugin::BotCommand;

 my @channels = ('#channel1', '#channel2');
 my $dns = POE::Component::Client::DNS->spawn();
 my $irc = POE::Component::IRC->spawn(
     nick   => 'YourBot',
     server => 'some.irc.server',
 );

 POE::Session->create(
     package_states => [
         main => [ qw(_start irc_001 irc_botcmd_slap irc_botcmd_lookup dns_response) ],
     ],
 );

 $poe_kernel->run();

 sub _start {
     $irc->plugin_add('BotCommand', POE::Component::IRC::Plugin::BotCommand->new(
         Commands => {
             slap   => 'Takes one argument: a nickname to slap.',
             lookup => 'Takes two arguments: a record type (optional), and a host.',
         }
     ));
     $irc->yield(register => qw(001 botcmd_slap botcmd_lookup));
     $irc->yield(connect => { });
 }

 # join some channels
 sub irc_001 {
     $irc->yield(join => $_) for @channels;
     return;
 }

 # the good old slap
 sub irc_botcmd_slap {
     my $nick = (split /!/, $_[ARG0])[0];
     my ($where, $arg) = @_[ARG1, ARG2];
     $irc->yield(ctcp => $where, "ACTION slaps $arg");
     return;
 }

 # non-blocking dns lookup
 sub irc_botcmd_lookup {
     my $nick = (split /!/, $_[ARG0])[0];
     my ($where, $arg) = @_[ARG1, ARG2];
     my ($type, $host) = $arg =~ /^(?:(\w+) )?(\S+)/;

     my $res = $dns->resolve(
         event => 'dns_response',
         host => $host,
         type => $type,
         context => {
             where => $where,
             nick  => $nick,
         },
     );
     $poe_kernel->yield(dns_response => $res) if $res;
     return;
 }

 sub dns_response {
     my $res = $_[ARG0];
     my @answers = map { $_->rdatastr } $res->{response}->answer() if $res->{response};

     $irc->yield(
         'notice',
         $res->{context}->{where},
         $res->{context}->{nick} . (@answers
             ? ": @answers"
             : ': no answers for "' . $res->{host} . '"')
     );

     return;
 }

DESCRIPTION
POE::Component::IRC::Plugin::BotCommand is a POE::Component::IRC plugin. It provides you with a standard interface to define bot commands and lets you know when they are issued. Commands are accepted as channel or private messages.

The plugin will respond to the 'help' command by default, listing available commands and information on how to use them. However, if you add a help command yourself, that one will be used instead.

METHODS

  "new"
Four optional arguments:

'Commands', a hash reference, with your commands as keys, and usage information as values. If the usage string contains newlines, the component will send one message for each line.

'In_channels', a boolean value indicating whether to accept commands in channels. Default is true.

'In_private', a boolean value indicating whether to accept commands in private. Default is true.

'Addressed', requires users to address the bot by name in order to issue commands. Default is true.

'Prefix', if 'Addressed' is false, all channel commands must be prefixed with this string. Default is '!'. You can set it to '' to allow bare channel commands.

'Ignore_unknown', if true, the plugin will ignore undefined commands, rather than printing a help message upon receiving them. Default is false.

'Eat', set to true to make the plugin hide "irc_public" events from other plugins if they contain a valid command. Default is false.

Returns a plugin object suitable for feeding to POE::Component::IRC's "plugin_add" method.

  "add"
Adds a new command. Takes two arguments, the name of the command, and a string containing its usage information. Returns false if the command has already been defined, true otherwise.

  "remove"
Removes a command. Takes one argument, the name of the command. Returns false if the command wasn't defined to begin with, true otherwise.

  "list"
Takes no arguments. Returns a list of key/value pairs, the keys being the command names and the values being the usage strings.

OUTPUT

  "irc_botcmd_*"
You will receive an event like this for every valid command issued. E.g. if 'slap' were a valid command, you would receive an "irc_botcmd_slap" event every time someone issued that command. "ARG0" is the nick!hostmask of the user who issued the command. "ARG1" is the name of the channel in which the command was issued, or the sender's nickname if this was a private message. If the command was followed by any arguments, "ARG2" will be a string containing them, otherwise it will be undefined.

TODO
Add permissions/authorization. E.g. allow the user to specify if commands are only available ops, or only to users matching some IRC masks, etc.

It would have to support permissions/auth on a per-command level, so that a bot can get by with a single BotCommand plugin, with respect to easily listing the available commands in a help message. Maybe augmenting the "add()" method to accept an optional hash reference argument detailing authorization requirements is appropriate here. I suppose plugins that call "add()" to add new commands should accept a hash reference like that as an 'auth' argument to their constructor.

I considered having the auth settings apply to all commands, and using multiple BotCommand plugins to group commands by who is allowed to issue them, but this approach is more complex if we want the bot to complain about undefined commands, or when someone wants a list of all commands. Plugins which define new commands would accept a 'botcmd' parameter to choose which BotCommand plugin they should call "add()"/"remove()" on.

Some prior art to consider:

POE::Component::IRC::Plugin::BaseWrap
Bot::BasicBot::Pluggable::Module::Auth

AUTHOR
Hinrik Oern Sigurd`sson, hinrik.sig@gmail.com