Moose::Util::MetaRole(3p)

NAME
Moose::Util::MetaRole - Apply roles to any metaclass, as well as the object base class

SYNOPSIS
  package MyApp::Moose;

  use Moose ();
  use Moose::Exporter;
  use Moose::Util::MetaRole;

  use MyApp::Role::Meta::Class;
  use MyApp::Role::Meta::Method::Constructor;
  use MyApp::Role::Object;

  Moose::Exporter->setup_import_methods( also => 'Moose' );

  sub init_meta {
      shift;
      my %options = @_;

      Moose->init_meta(%options);

      Moose::Util::MetaRole::apply_metaclass_roles(
          for_class               => $options{for_class},
          metaclass_roles         => ['MyApp::Role::Meta::Class'],
          constructor_class_roles => ['MyApp::Role::Meta::Method::Constructor'],
      );

      Moose::Util::MetaRole::apply_base_class_roles(
          for_class => $options{for_class},
          roles     => ['MyApp::Role::Object'],
      );

      return $options{for_class}->meta();
  }

DESCRIPTION
This utility module is designed to help authors of Moose extensions write extensions that are able to cooperate with other Moose extensions. To do this, you must write your extensions as roles, which can then be dynamically applied to the caller's metaclasses.

This module makes sure to preserve any existing superclasses and roles already set for the meta objects, which means that any number of extensions can apply roles in any order.

USAGE
It is very important that you only call this module's functions when your module is imported by the caller. The process of applying roles to the metaclass reinitializes the metaclass object, which wipes out any existing attributes already defined. However, as long as you do this when your module is imported, the caller should not have any attributes defined yet.

The easiest way to ensure that this happens is to use Moose::Exporter, which can generate the appropriate "init_meta" method for you, and make sure it is called when imported.

FUNCTIONS
This module provides two functions.

  apply_metaclass_roles( ... )
This function will apply roles to one or more metaclasses for the specified class. It accepts the following parameters:

•   for_class => $name

    This specifies the class for which to alter the meta classes.

•   metaclass_roles => \@roles

•   attribute_metaclass_roles => \@roles

•   method_metaclass_roles => \@roles

•   wrapped_method_metaclass_roles => \@roles

•   instance_metaclass_roles => \@roles

•   constructor_class_roles => \@roles

•   destructor_class_roles => \@roles

•   application_to_class_class_roles => \@roles

•   application_to_role_class_roles => \@roles

•   application_to_instance_class_roles => \@roles

    These parameter all specify one or more roles to be applied to the specified metaclass. You can pass any or all of these parameters at once.

  apply_base_class_roles( for_class => $class, roles => \@roles )
This function will apply the specified roles to the object's base class.

AUTHOR
Dave Rolsky <autarch@urth.org>

COPYRIGHT AND LICENSE
Copyright 2009 by Infinity Interactive, Inc.

<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.