Appender::Socket(3)

NAME
Log::Log4perl::Appender::Socket - Log to a socket

SYNOPSIS
    use Log::Log4perl::Appender::Socket;

    my $appender = Log::Log4perl::Appender::Socket->new(
      PeerAddr => "server.foo.com",
      PeerPort => 1234,
    );

    $appender->log(message => "Log me\n");

DESCRIPTION
This is a simple appender for writing to a socket. It relies on IO::Socket::INET and offers all parameters this module offers.

Upon destruction of the object, pending messages will be flushed and the socket will be closed.

If the appender cannot contact the server during the initialization phase (while running the constructor "new"), it will "die()".

If the appender fails to log a message because the socket's "send()" method fails (most likely because the server went down), it will try to reconnect once. If it succeeds, the message will be sent. If the reconnect fails, a warning is sent to STDERR and the "log()" method returns, discarding the message.

If the option "silent_recovery" is given to the constructor and set to a true value, the behaviour is different: If the socket connection can't be established at initialization time, a single warning is issued. Every log attempt will then try to establish the connection and discard the message silently if it fails.

EXAMPLE
Write a server quickly using the IO::Socket::INET module:

    use IO::Socket::INET;

    my $sock = IO::Socket::INET->new(
        Listen    => 5,
        LocalAddr => 'localhost',
        LocalPort => 12345,
        Proto     => 'tcp');

    while(my $client = $sock->accept()) {
        print "Client connected\n";
        while(<$client>) {
            print "$_\n";
        }
    }

Start it and then run the following script as a client:

    use Log::Log4perl qw(:easy);

    my $conf = q{
        log4perl.category                  = WARN, Socket
        log4perl.appender.Socket           = Log::Log4perl::Appender::Socket
        log4perl.appender.Socket.PeerAddr  = localhost
        log4perl.appender.Socket.PeerPort  = 12345
        log4perl.appender.Socket.layout    = SimpleLayout
    };

    Log::Log4perl->init(\$conf);

    sleep(2);

    for(1..10) {
        ERROR("Quack!");
        sleep(5);
    }

AUTHOR
Mike Schilli <log4perl@perlmeister.com>, 2003